CF8 和 AES 解密 MySQL AES：编码不同

这已经成为一种练习，告诉我我做错了什么，而不是关键任务，但我仍然想看看我犯了什么（可能很简单）的错误。

我正在使用 mysql (5.1.x) AES_ENCRYPT 来加密字符串。我正在使用 CF 的generateSecretKey('AES') 来制作密钥（我已经尝试过默认长度、128 和 256 位长度）。

假设我的代码如下所示：

    <cfset key = 'qLHVTZL9zF81kiTnNnK0Vg=='/>
    <cfset strToEncrypt = '4111111111111111'/>
    <cfquery name="i" datasource="#dsn#">
        INSERT INTO table(str) 
            VALUES AES_ENCRYPT(strToEncrypt,'#key#');
    </cfquery>

这按预期工作正常，我可以使用 SELECT AES_DECRYPT(str,'#key#') AS 选择它，没有任何问题。

但我似乎无法做的是让 CF 使用类似以下内容来解密它：

    <cfquery name="s" datasource="#dsn#">
        SELECT str
          FROM table
    </cfquery>
    <cfoutput>#Decrypt(s.str,key,'AES')#</cfoutput>

or

    <cfoutput>#Decrypt(toString(s.str),key,'AES')#</cfoutput>

我不断收到“输入和输出编码不相同”（包括 toString() - 如果没有，我会收到二进制数据错误）。数据库中加密字符串的字段类型是 blob。

此条目 http://info.michael-simons.eu/2011/07/18/mysql-compatible-aes-encryption-decryption-in-java/解释说 mySQL 处理 AES-128 密钥的方式与您想象的有点不同：

.. MySQL 算法只是 or 给定密码短语的字节 如果密码长度超过 16 个字符，则针对前面的字节 当密码短于 16 个字符时，将它们保留为 0。

没有经过严格测试，但这似乎产生相同的结果（以十六进制表示）。

<cfscript>
    function getMySQLAES128Key( key ) {
        var keyBytes   = charsetDecode( arguments.key, "utf-8" );
        var finalBytes = listToArray( repeatString("0,", 16) );

        for (var i = 1; i <= arrayLen(keyBytes); i++) {
            // adjust for base 0 vs 1 index
            var pos = ((i-1) % 16) + 1;
            finalBytes[ pos ] = bitXOR(finalBytes[ pos ], keyBytes[ i ]);
        }

        return binaryEncode( javacast("byte[]", finalBytes ), "base64" );
    }

    key     = "qLHVTZL9zF81kiTnNnK0Vg==";
    input   = "4111111111111111";

    encrypted = encrypt(input, getMySQLAES128Key(key), "AES", "hex");
    WriteDump("encrypted="& encrypted);

    // note: assumes input is in "hex". either convert the bytes 
    // to hex in mySQL first or use binaryEncode
    decrypted = decrypt(encrypted, getMySQLAES128Key(key), "AES", "hex");
    WriteDump("decrypted="& decrypted);
</cfscript>

Note:如果您使用 mySQL 进行加密，请务必查看其文档，其中提到纯文本可能最终出现在各种日志中 http://dev.mysql.com/doc/refman/5.5/en/encryption-functions.html（复制、历史等）并且“可以由任何有权读取该信息的人阅读”。

Update:情况可能已经改变，但根据2004 年的错误报告 http://bugs.mysql.com/bug.php?id=3172 the .mysql_history文件仅在 Unix 上存在。 （记住可能还有其他日志文件）清除.mysql_history的详细说明可以说明书上找到的 http://dev.mysql.com/doc/refman/5.0/en/mysql-history-file.html，但总而言之：

• Set the MYSQL_HISTFILE变量为 /dev/null （每次登录时）
• 创建 .mysql_history 作为 /dev/null 的符号链接（仅一次）