此刻,我有一个WorkLog
类型,并带有开始日期和结束日期。我还想添加一个持续时间镜头,它将从开始日期和结束日期派生出来。它应该是只读的,或者如果其值发生更改则更改结束日期(我想知道如何实现这两个版本,即使我只会使用一个版本)。
这是我的代码。基本上,如果你能实现workLogDurationRO
and workLogDurationRW
函数来获得主要传递中的所有测试,这将回答我的问题。
{-# LANGUAGE TemplateHaskell #-}
module Main where
import Control.Lens
-- Keep times simple for this example
newtype TimeStamp = TimeStamp Int deriving (Show, Eq)
newtype TimeDifference = TimeDifference Int deriving (Show, Eq)
(-.-) :: TimeStamp -> TimeStamp -> TimeDifference
(TimeStamp a) -.- (TimeStamp b) = TimeDifference (a - b)
data WorkLog = WorkLog {
_workLogDescription :: String
, _workLogStartTime :: TimeStamp
, _workLogEndTime :: TimeStamp
}
makeLenses ''WorkLog
-- | Just return the difference between the start and end time
workLogDurationRO :: Getter WorkLog TimeDifference
workLogDurationRO = error "TODO write me!"
-- | Like the read only version, but when used with a setter,
-- change the end date.
workLogDurationRW :: Lens' WorkLog TimeDifference
workLogDurationRW = error "TODO write me!"
ensure :: String -> Bool -> IO ()
ensure _ True = putStrLn "Test Passed"
ensure msg False = putStrLn $ "Test Failed: " ++ msg
main :: IO ()
main = do
let testWorkLog = WorkLog "Work 1" (TimeStamp 40) (TimeStamp 100)
ensure "read only lens gets correct duration" $
testWorkLog^.workLogDurationRO == TimeDifference 60
ensure "read+write lens gets correct duration" $
testWorkLog^.workLogDurationRW == TimeDifference 60
let newWorkLog = testWorkLog & workLogDurationRW .~ TimeDifference 5
ensure "writeable lens changes end time" $
newWorkLog^.workLogEndTime == TimeStamp 45
你可以写下Getter
using to
(你可以给-.-
降低优先级以去掉括号):
workLogDurationRO = to $ \wl -> (wl^.workLogEndTime) -.- (wl^.workLogStartTime)
但作为镜头维基 https://github.com/ekmett/lens/wiki/FAQ#wiki-using-getters说,你可能最好使用一个计算时间差的普通函数,然后你可以使用它to
当您需要它作为镜头时。
您可以构建Lens'
来自 getter(与上面相同)和 setter:
workLogDurationRW = lens get set
where
get :: WorkLog -> TimeDifference
get wl = (wl^.workLogEndTime) -.- (wl^.workLogStartTime)
set :: WorkLog -> TimeDifference -> WorkLog
set wl timeDiff = wl & workLogEndTime .~ (wl^.workLogStartTime) +.+ timeDiff
where
TimeStamp a +.+ TimeDifference b = TimeStamp (a + b)
本文内容由网友自发贡献,版权归原作者所有,本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容,请联系:hwhale#tublm.com(使用前将#替换为@)