修复了开发办公套件时 Visual Basic 中 FontSize 函数的错误

在花了几个小时研究 FontSize 函数后，我被一段代码困住了。字体列表，每当我想定义每个字体具有相同的大小时，它会自动将其缩放到72。

我浏览了互联网以了解如何获取字体列表，这很有效，但是当我将 fontSize 添加到 sizecombo 组合框时，它变得疯狂。

Imports System.Drawing.Text

Public Class wordking
    Dim fontSize As Integer = 8
    Private Sub wordking_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim myFont As New InstalledFontCollection

        For Each FontName As FontFamily In myFont.Families
            fontcombo.Items.Add(FontName.Name)
        Next
        For fontSize = 8 To 72 Step 2
            sizecombo.Items.Add(fontSize)
        Next
    End Sub
    Private Sub fontcombo_SelectedIndexChanged(sender As Object, e As EventArgs) Handles fontcombo.SelectedIndexChanged
        wordbox.SelectionFont = New Font(fontcombo.Text, fontSize, FontStyle.Regular)
    End Sub

    Private Sub sizecombo_SelectedIndexChanged(sender As Object, e As EventArgs) Handles sizecombo.SelectedIndexChanged
        Dim currentfontSize As Single = Convert.ToSingle(sizecombo.Text)
        wordbox.SelectionFont = New Font(wordbox.SelectionFont.FontFamily, currentfontSize)
    End Sub

    Private Sub ExitToolStripMenuItem_Click(sender As Object, e As EventArgs) Handles ExitToolStripMenuItem.Click
        mainmenu.Show()
        Me.Close()
    End Sub
End Class

我期望该函数显示字体列表，它确实做到了，但它也将字体大小调整为我的最大值 72。这个错误让我很恼火。

以下几点可能会有所帮助：

• 要填充组合框：

cmbFont.DataSource = New InstalledFontCollection().Families
cmbFont.DisplayMember = "Name"

For i As Integer = 8 To 72 Step 2
    cmbFontSize.Items.Add(i)
Next

'Assuming the target control is a TextBox:
cmbFont.SelectedIndex = cmbFont.Items.IndexOf(TextBox1.Font.FontFamily)
cmbFontSize.Text = TextBox1.Font.Size.ToString

• 创建一个子项来更改将从组合框的引发事件中调用的字体：

Private Sub SetFont()
    If cmbFont.SelectedItem Is Nothing OrElse String.IsNullOrEmpty(cmbFontSize.Text) Then
        Return
    End If

    Dim fnt As FontFamily = DirectCast(cmbFont.SelectedItem, FontFamily)
    Dim fntSize As Single = Convert.ToSingle(cmbFontSize.Text)
    Dim fntStyle As FontStyle

    For Each fs As FontStyle In [Enum].GetValues(GetType(FontStyle))
        If fnt.IsStyleAvailable(fs) Then
            fntStyle = fs
            Exit For
        End If
    Next

    TextBox1.Font = New Font(fnt, fntSize, fntStyle)
End Sub

请注意，您还需要检查新选择的字体的 FontStyle 是否提供常规样式（我在代码中看到您更喜欢常规样式）是否可用。如果没有，将选择第一个可用的样式。

• 处理字体 SelectedIndexChanged 事件：

Private Sub cmbFont_SelectedIndexChanged(sender As Object, e As EventArgs) Handles cmbFont.SelectedIndexChanged
    SetFont()
End Sub

• 我认为最好处理尺寸组合框的 TextChanged 事件，以便用户可以输入非列出的值，例如 11、13 等：

Private Sub cmbFontSize_TextChanged(sender As Object, e As EventArgs) Handles cmbFontSize.TextChanged
    SetFont()
End Sub

如果您还需要将组合框与文本编辑器链接起来，以便在选择更改时显示选择字体，那么您可以执行以下操作：

• 添加一个类变量并为其命名；

Private IsSelectionChanged As Boolean = False

这将用于避免裁员。

• 添加 sub 以从选择中获取字体：

Private Sub GetFont()
    IsSelectionChanged = True

    Dim fnt As Font = If(txtEditor.SelectionFont, txtEditor.Font)

    cmbFont.SelectedIndex = cmbFont.Items.IndexOf(fnt.FontFamily)
    cmbFontSize.Text = fnt.Size.ToString

    IsSelectionChanged = False
End Sub

• 更改 SetFont 子项中的第一行，如下所示：

Private Sub SetFont()
    If IsSelectionChanged OrElse cmbFont.SelectedItem Is Nothing OrElse String.IsNullOrEmpty(cmbFontSize.Text) Then
        Return
    End If
'
'
'The rest as the above mentioned...
End Sub

• 在编辑器的选择更改事件中：

Private Sub txtEditor_SelectionChanged(sender As Object, e As EventArgs) Handles txtEditor.SelectionChanged
    GetFont()
End Sub

就这样。只需调整它即可满足您的要求。

这是一个快速演示：

祝你好运。