带有 alpha 混合图标的图像列表失去透明度

这是（或多或少）一个相关的问题：Delphi - 在运行时用图标填充图像列表会“破坏”透明度 https://stackoverflow.com/questions/3056889/delphi-populate-an-imagelist-with-icons-at-runtime-destroys-transparency.

我已经测试过@TOndrejanswer https://stackoverflow.com/a/3061520/937125。但似乎我需要启用视觉样式（XP Manifest）才能使其工作（将使用 Windows 通用控件 6.0 版本 - 我现在不想要）。我在运行时添加图标ExtractIconEx and ImageList_AddIcon.

显然设置ImageList.Handle使用系统图像列表句柄，does not需要 XP 清单。因此，当我使用系统图像列表显示文件列表（使用TListView).

我在徘徊系统图像列表有什么特别之处以及它是如何创建的，以便它在所有情况下都支持 alpha 混合？我无法弄清楚这一点。这是一些示例代码：

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Menus, ImgList, StdCtrls, ShellAPI, ExtCtrls, Commctrl;

type
  TForm1 = class(TForm)
    ImageList1: TImageList;
    PopupMenu1: TPopupMenu;
    MenuItem1: TMenuItem;
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    FileName: string;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}
// {$R WindowsXP.res}

procedure TForm1.FormCreate(Sender: TObject);
begin
  PopupMenu1.Images := ImageList1;
  FileName := 'C:\Program Files\Mozilla Firefox\firefox.exe';
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  IconPath: string;
  IconIndex: Integer;
  hIconLarge, hIconSmall: HICON;
begin
  IconPath := FileName;
  IconIndex := 0; // index can be other than 0

  ExtractIconEx(PChar(IconPath), IconIndex, hIconLarge, hIconSmall, 1);

  Self.Refresh; // erase form
  DrawIconEx(Canvas.Handle, 10, 10, hIconSmall, 0, 16, 16, 0,
    DI_IMAGE or DI_MASK); // this will draw ok on the form

  // ImageList1.DrawingStyle := dsTransparent;
  ImageList1.Handle := ImageList_Create(ImageList1.Width, ImageList1.Height,
    {ILC_COLORDDB} ILC_COLOR32 or ILC_MASK, 0, ImageList1.AllocBy);
  ImageList_AddIcon(ImageList1.Handle, hIconSmall);

  MenuItem1.ImageIndex := 0;

  DestroyIcon(hIconSmall);
  DestroyIcon(hIconLarge);

  PopupMenu1.Popup(Mouse.CursorPos.X, Mouse.CursorPos.Y);
end;

procedure TForm1.Button2Click(Sender: TObject);
// using sys image-list will work with or without Manifest
type
  DWORD_PTR = DWORD;
var
  ShFileINfo :TShFileInfo;
  SysImageList: DWORD_PTR;
  FileName: string;
begin
  SysImageList := ShGetFileInfo(nil, 0, ShFileInfo, SizeOf(ShFileInfo),
    SHGFI_SYSICONINDEX OR SHGFI_SMALLICON);

  if SysImageList = 0 then Exit;
  ImageList1.Handle := SysImageList;
  ImageList1.ShareImages := True;

  if ShGetFileInfo(PChar(FileName), 0, ShFileInfo, SizeOf(ShFileInfo),
    SHGFI_SYSICONINDEX OR SHGFI_ICON OR SHGFI_SMALLICON) <> 0 then
  begin
    MenuItem1.ImageIndex := ShFileInfo.IIcon;
    Self.Refresh; // erase form
    DrawIconEx(Canvas.Handle, 10, 10, ShFileInfo.hIcon, 0, 16, 16, 0,
      DI_IMAGE or DI_MASK);
    DestroyIcon(ShFileInfo.hIcon); // todo: do I need to destroy here? 

    PopupMenu1.Popup(Mouse.CursorPos.X, Mouse.CursorPos.Y);
  end;      
end;

end.

视觉风格Disabled:

视觉风格Enabled:

解决方法是使用插入器类或子类TImageList并覆盖DoDraw 如图所示 https://stackoverflow.com/q/9877718/937125，但我真正想知道的是如何创建与系统图像列表相同的图像列表。

注：我知道TPngImageList并且不想在这种情况下使用它。

Edit:@David 的回答（和评论）是准确的：

您必须显式链接到 ImageList_Create (v6)，因为 否则它会在模块加载时隐式链接并且将被 绑定到 v5.8

示例代码（不使用激活上下文 API）：

function ImageList_Create_V6(CX, CY: Integer; Flags: UINT; Initial, Grow: Integer): HIMAGELIST;
var
  h: HMODULE;
  _ImageList_Create: function(CX, CY: Integer; Flags: UINT;
    Initial, Grow: Integer): HIMAGELIST; stdcall;
begin
  // TODO: find comctl32.dll v6 path programmatically
  h := LoadLibrary('C:\WINDOWS\WinSxS\x86_Microsoft.Windows.Common-Controls_6595b64144ccf1df_6.0.2600.5512_x-ww_35d4ce83\comctl32.dll');
  if h <> 0 then
  try
    _ImageList_Create := GetProcAddress(h, 'ImageList_Create');
    if Assigned(_ImageList_Create) then
      Result := _ImageList_Create(CX, CY, Flags, Initial, Grow);
  finally
    FreeLibrary(h);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  ...
  ImageList1.Handle := ImageList_Create_V6(ImageList1.Width, ImageList1.Height,
    ILC_COLOR32 or ILC_MASK, 0, ImageList1.AllocBy);
  ...
end;

Edi2: @David 的示例代码 http://pastebin.com/dvMiGJ78这显示了如何通过 Activation Context API 正确完成此操作。

图像列表控件有两个版本。 v5.8版本和v6版本。系统镜像列表是系统拥有的共享组件，使用v6版本。它没有任何其他特殊之处，它只是一个普通的 v6 图像列表。在您的应用程序中，您的图像列表是 v5.8 或 v6，具体取决于您是否包含清单。但系统拥有的镜像列表始终是v6。

我不知道为什么你不想在你的应用程序中使用 v6 通用控件。但有了这个限制，您可以在创建图像列表时使用激活上下文 API 在本地使用 v6 通用控件。这将解决您的问题，并让应用程序的其余部分保留 v5.8 通用控件。