我可以使用 Access VBA 来确定表是否具有数据宏吗？

有没有办法通过 VBA 确定 Access 表是否包含数据宏？我有数据宏most我的表，但是如果我的代码遇到没有它的表，则会失败。

我没有收到错误消息。相反，代码会继续运行，就像处于无限循环中一样，但我必须强制 Access 退出才能逃脱。

具体来说，我试图保存所有表格和数据宏，以便稍后可以使用（未​​记录的）LoadFromText 函数重新创建它们。

我在下面的代码示例中用 ** BUG ** 突出显示了该问题。

For Each td In db.TableDefs 
    If Left(td.Name, 4) <> "MSys" Then

        'Save the table as a text file.        
        DoCmd.TransferText acExportDelim, , td.Name, sExportLocation & "Table_" & td.Name & ".txt", True

        'Save the table's data macro as an XML file. 
        '** BUG **: If a table doesn't have a data macro, Access freezes/starts infinite loop.
        Application.SaveAsText acTableDataMacro, td.Name, sExportLocation & "Table_" & td.Name & "_DataMacro.xml"

    End If
Next td

我假设我需要某种嵌套的 If 语句，首先检查表中是否存在数据宏。但我不知道该怎么写。

感谢指出 SaveAsText 和 LoadFromText 函数的人们在另一个SO帖子中 https://stackoverflow.com/questions/9206153/how-to-export-access-2010-data-macros。这些功能似乎有很大的潜力。

您可以使用简单的查询来指示表是否具有数据宏：

SELECT [Name] FROM MSysObjects WHERE Not IsNull(LvExtra) and Type =1

该宏可以应用于问题中的 VBA 代码，如下所示：

For Each td In db.TableDefs
    If Left(td.Name, 4) <> "MSys" Then

        'Save the table as a text file.
        DoCmd.TransferText acExportDelim, , td.Name, sExportLocation & _
            "Table_" & td.Name & ".txt", True

        'Define a recordset to determine if the table has a data macro.
        sql = "SELECT [Name] FROM MSysObjects WHERE Not IsNull(LvExtra) and " & _
            "Type = 1 and [Name] = '" & td.Name & "'"
        Set rst = db.OpenRecordset(sql, dbOpenSnapshot)

        'If the table has a data macro, save the data macro as an XML file.
        If rst.RecordCount <> 0 Then
            Application.SaveAsText acTableDataMacro, td.Name, sExportLocation & _
                "Table_" & td.Name & "_DataMacro.xml"
        End If

        'Close the recordset and clear its variable.
        If Not rst Is Nothing Then
            rst.Close
            Set rst = Nothing
        End If

    End If
Next td

信用去往UtterAccess 上的帖子 http://www.utteraccess.com/wiki/index.php/Document_Data_Macros and @Scotch 对 SO 问题的回答 https://stackoverflow.com/questions/16244608/how-to-list-datamacro-objects-in-an-access-database引用了 UtterAccess 帖子。