系统找不到指定的路径（批处理文件） - 使用带有空格的路径 - PENTAHO Spoon.bat (pdi-ce-7.1.0.0-12)

我试图从 PENTAHO (pdi-ce-7.1.0.0-12) 执行批处理文件“spoon.bat”，但出现错误。

发现错误的批处理文件部分：

if "%SPOON_CONSOLE%"=="1" set PENTAHO_JAVA=C:\Program Files (x86)\Java\jre1.8.0_121\bin\java.exe
if not "%SPOON_CONSOLE%"=="1" set PENTAHO_JAVA=C:\Program Files (x86)\Java\jre1.8.0_121\bin\javaw.exe
set IS64BITJAVA=0
call "%~dp0set-pentaho-env.bat"

但我收到以下错误：

The system cannot find the path specified

错误是当我尝试将找到 java.exe 或 javaw.exe 的路径分配给“PENTAHO_JAVA”时。

我用双引号修改了路径，但不起作用；我也修改为：

if "%SPOON_CONSOLE%"=="1" set "PENTAHO_JAVA=C:\<Program Files (x86)>\Java\jre1.8.0_121\bin\java.exe"

知道如何声明它来修复它吗？

环境变量在哪里PENTAHO_JAVA参考？

必须引用它"%PENTAHO_JAVA%"因为分配给该环境变量的字符串包含空格或等字符&()[]{}^=;!'+,`~。在命令提示符窗口中运行的 Windows 命令解释器输出的帮助中对此进行了解释cmd /?在最后一个帮助页面的最后一段中。

当然也可以定义环境变量并添加必要的双引号，即使用：

if     "%SPOON_CONSOLE%"=="1" set "PENTAHO_JAVA="%ProgramFiles(x86)%\Java\jre1.8.0_121\bin\java.exe""
if not "%SPOON_CONSOLE%"=="1" set "PENTAHO_JAVA="%ProgramFiles(x86)%\Java\jre1.8.0_121\bin\javaw.exe""
set "IS64BITJAVA=0"
call "%~dp0set-pentaho-env.bat"

但不建议这样做。更好的是使用

if     "%SPOON_CONSOLE%"=="1" set "PENTAHO_JAVA=%ProgramFiles(x86)%\Java\jre1.8.0_121\bin\java.exe"
if not "%SPOON_CONSOLE%"=="1" set "PENTAHO_JAVA=%ProgramFiles(x86)%\Java\jre1.8.0_121\bin\javaw.exe"
set "IS64BITJAVA=0"
call "%~dp0set-pentaho-env.bat"

和参考环境变量PENTAHO_JAVA如果需要指定用双引号括起来的值，则用双引号括起来。

Example:

@echo off
rem Get path of latest installed Java directly from Windows registry.
for /F "skip=1 tokens=1,2*" %%N in ('%SystemRoot%\System32\reg.exe QUERY "HKLM\Software\Microsoft\Windows\CurrentVersion\App Paths\javaws.exe" /v Path 2^>nul') do if /I "%%N" == "Path" set "PENTAHO_JAVA=%%P" & goto JavaPathFound

rem Path of Java not found in registry, search for 32-bit Java in the default
rem program files folders of 64-bit and 32-bit Windows and take first found.
if "%ProgramFiles(x86)%" == "" goto Windows_x86
for /R "%ProgramFiles(x86)%" %%I in (java*.exe) do set "PENTAHO_JAVA=%%~dpI" & goto JavaPathFound
:Windows_x86
for /R "%ProgramFiles%" %%I in (java*.exe) do set "PENTAHO_JAVA=%%~dpI" & goto JavaPathFound

echo Error: Java binary directory not found.
echo/
pause
goto :EOF

:ErrorJavaEXE
echo Error: File %PENTAHO_JAVA% not found.
echo/
pause
goto :EOF

:JavaPathFound
if not "%PENTAHO_JAVA:~-1%" == "\" set "PENTAHO_JAVA=%PENTAHO_JAVA%\"
if "%SPOON_CONSOLE%" == "1" (
    set "PENTAHO_JAVA=%PENTAHO_JAVA%java.exe"
) else (
    set "PENTAHO_JAVA=%PENTAHO_JAVA%javaw.exe"
)

rem Check existence of Java executable to run.
if not exist "%PENTAHO_JAVA%" goto ErrorJavaEXE

"%PENTAHO_JAVA%" -version
call "%~dp0set-pentaho-env.bat"

为了了解所使用的命令及其工作原理，请打开命令提示符窗口，执行以下命令，并仔细阅读为每个命令显示的所有帮助页面。

• call /?
• echo /?
• for /?
• goto /?
• if /?
• pause /?
• reg /?
• reg query /?
• rem /?

另请阅读 Microsoft 的文章：使用命令重定向运算符 https://technet.microsoft.com/en-us/library/bb490982.aspx的解释2>nul其中重定向运算符必须在此批处理代码中转义FOR带有插入符号的命令行^。并阅读答案使用 Windows 批处理文件的单行多个命令 https://stackoverflow.com/questions/25343351/的解释&操作员。