在正确的时机批量创建视频 .srt 字幕

好家伙！我什至不知道从什么开始）所以，我有一个包含很多视频的文件夹。我需要的是使用这些视频的名称创建字幕，同时注意其长度以创建 .srt 格式的字幕。

我已经查找了一些信息并复制了一些代码

@echo off  
set dirpath=%1 
dir C:\FolderwithVideos /O:S /b /-p /o:gn > "C:\result.txt"
call replacer.bat result.txt ".mp4" ""
exit

结果我在 result.txt 中得到了这个

 videoname1
 videoname2
 videoname3

我需要的是让它们看起来像这样（当然最后用结果创建 .srt 文件。）

1
00:00:0,000 --> 00:00:25,000
videoname1

2
00:00:25,000 --> 00:00:35,000
videoname2

3
00:00:35,000 --> 00:00:55,000
videoname3

希望我得到了一切，请帮助！提前致谢！

使用VBS获取每个视频文件的视频长度（使用文件夹.GetDetailsOf 方法） http://msdn.microsoft.com/en-us/library/windows/desktop/bb787870%28v=vs.85%29.aspx and to sum定时器的长度.srt文件（使用格式日期时间函数） https://msdn.microsoft.com/en-us/library/8aebkz6s%28v=vs.84%29.aspx.

该脚本获取 result.txt 文件中视频的名称（因此您必须在此脚本中包含您的代码）BAT或者运行之前生成它的蝙蝠。

我已经将它包含在我的代码中但是REM前。所以删除REMs如果需要的话。

结果显示在CMD上并写入文件Output.srt（与BAT文件同级目录下）

构建Srt.bat

@echo off&cls

::The Path of your Videos files

set "$VideoPath=C:\FolderwithVideos"

::If you want your Code in this BAT remove the REMs Below :

rem dir "%$VideoPath%" /O:S /b /-p /o:gn > "C:\result.txt"
rem call replacer.bat result.txt ".mp4" ""

setlocal enabledelayedexpansion
set /a $Count=1
set "$Timer=00:00:00"


(for /f "delims=" %%a in (result.txt) do (
  call:getVideolength "%%a.mp4"
  for /f "delims=" %%x in ('cscript //nologo getvideolength.vbs') do (
       call:SumTime !$Timer! %%x
       for /f "delims=" %%y in ('cscript //nologo SumTime.vbs') do set "$NewTimer=%%y"
       echo !$Count!
       echo !$Timer!,000 --^> !$NewTimer!,000
       echo %%a
       Set $Timer=!$NewTimer!
  )
  set /a $Count+=1
))>Output.srt

echo Done !!!
type Output.srt
pause
exit/b

:GetVideoLength
(echo dim objShell
echo dim objFolder
echo dim objFolderItem
echo set objShell = CreateObject("shell.application"^)
echo set objFolder = objShell.NameSpace("%$videoPath%"^)
echo set objFolderItem = objFolder.ParseName(%1^)
echo dim objInfo
echo objInfo = objFolder.GetDetailsOf(objFolderItem, 27^)
echo wscript.echo objinfo)>GetVideoLength.vbs
exit/b


:SumTime
echo wscript.echo FormatDateTime(CDate("%1"^) + CDate("%2"^),3^) >SumTime.vbs
exit/b

这将创建一个文件Output.srt像这样 ：

1
00:00:00,000 --> 01:28:28,000
Film1
2
01:28:28,000 --> 02:49:39,000
Film2
3
02:49:39,000 --> 04:45:25,000
Film3