用户表单 - 从私有子返回公共子

我有下面的代码，它是一个私有子，它是从公共子中的 Userform3.show 初始化的，据我所知，下面的代码可以工作，但完成后它不会返回到公共子。

请注意，当我更改sheet8.range(I16)的值时，另一个私有子被调用。但是我相信下面的代码是问题所在。

谁能告诉我如何让私人潜艇在完成后返回公共潜艇？

Private Sub UserForm_Initialize()
'populate "Combo-Box with Boards

With Me.ComboBox1
.Clear ' clear previous items (not to have "doubles")
.AddItem "BISSB"
.AddItem "MORIB"
.AddItem "RMIB"
End With
End Sub

Private Sub CommandButton1_Click()

If Me.ComboBox1.ListIndex = -1 Then
UserForm3.Hide
MsgBox "No board was selected, please re-run macro and select appropriate board"
Exit Sub

Else
Sheet8.Range("I16").Value = ComboBox1.Text

End If
End Sub

Private Sub CommandButton2_Click()
UserForm3.Hide
MsgBox "No board was selected, please re-run macro and select appropriate board"
End
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
 If CloseMode = 0 Then
    MsgBox "No board was selected, please re-run macro and select appropriate board"
    End
    End If
End Sub

公共子系统的开始

Sub newResumeAssessment_Click()
Dim answer As Variant
Dim Proceed As Boolean
Dim Uname As String

If UCase(Sheets("Main Menu").Range("A1")) = "YES" Then

answer = 6

Else

    answer = MsgBox("Click Yes to start a Business Case." & _
      vbCrLf & "Click No to resume the Business Case." & vbCrLf & _
      "Click Cancel to go back to the main menu." & vbNewLine & _
      vbNewLine & "Please note, you will need to load the board submission " & _
      "tracker before you start a new business case.", 35, "Business Case")

End If

If answer = 6 Then

UserForm3.Show

第一件事， 消除End，无处不在。End是一个红色的“NUKE 'EM ALL”按钮ends立即执行，然后 - 之后End已执行，无论您在调用堆栈中的位置如何，对于不再有调用堆栈;您的代码不再运行，无处可“返回”。

第二件事，不要将状态保留在默认实例的一种形式。像对待物体一样对待它，并且New当您需要时创建一个新实例 - 这样您就不需要被打扰Unload调用它和/或重置调用之间的状态：_Initialize处理程序每​​次都会运行，并且不需要Clear上次调用中的项目，因为您每次都将使用新的实例。你这样做：

With New UserForm3 'UserForm_Initialize handler runs here
    .Show 'UserForm_Activate handler runs here
    'anything after .Show will only run after the form is closed
    If Not .Cancelled Then
        Sheet8.Range("I16").Value = .ComboBox1.Text
    End If
End With 'UserForm_Terminate handler runs here

请注意，工作表并未由表单写入 -这不是它的工作！那么我们如何做到这一点Cancelled会员合法吗？

首先你命名事物和做CommandButton1 be OkButton and CommandButton2 be CancelButton- 或者其他什么 - 只是不是 Button1 和 Button2。

我喜欢你hiding表单实例而不是用核武器摧毁它Unload Me，不管你是明确地工作关​​闭默认实例再次，这意味着上面New UserForm3代码不会隐藏正在显示的同一实例。NEVER当您打算使用时，使用默认实例限定成员调用Me.

换句话说：

UserForm3.Hide 'hides the default instance of UserForm3

Me.Hide 'hides whatever the current instance is

Hide 'same as Me.Hide

所以。添加一个Private isCancelled As Boolean私有字段（模块级变量），然后公开一个Public Property Get Cancelled() As Boolean返回它的公共属性 getter：

Option Explicit
Private isCancelled As Boolean

Public Property Get Cancelled() As Boolean
    Cancelled = isCancelled
End Property

接下来，让您的取消按钮设置标志：

Private Sub CancelButton_Click()
    isCancelled = True
    Me.Hide
End Sub

然后使QueryClose处理程序也设置它 - 并尽可能使用现有的命名常量：

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    If CloseMode = vbFormControlMenu Then
        Cancel = True
        isCancelled = True
        Me.Hide
    End If
End Sub

然后在“确定”按钮的处理程序中实现“happy-path”逻辑：

Private Sub OkButton_Click()
    Me.Hide
End Sub

我会禁用“确定”按钮，直到用户做出选择 - 这样他们就可以取消、取消或做出有效的选择！

Public Property Get SelectedBoard() As String
    SelectedBoard = IIf(Me.ComboBox1.ListIndex = -1, vbNullString, Me.ComboBox1.Text)
End Property

Private Sub ComboBox1_Change()
    ValidateForm
End Sub

Private Sub ValidateForm()
    Me.OkButton.Enabled = (SelectedBoard <> vbNullString)
End Sub

Private Sub UserForm_Activate()
    ValidateForm
End Sub

现在调用者看起来像这样：

With New UserForm3
    .Show
    If Not .Cancelled Then
        Sheet8.Range("I16").Value = .SelectedBoard
    Else
        MsgBox "No board was selected, please re-run macro and select appropriate board"
    End If
End With

现在您有了一个窗体，它只不过是代码的 I/O 设备，正如它应该的那样。而且您使用的是对象而不是全局状态。

TL;DR:

• Remove End无论他们身在何处，都可以得到指导。
• 不参考UserForm3 inside UserForm3 (use Me反而）。
• 与新鲜人一起工作New每次都有实例。
• Expose Property Get供调用代码访问的成员，以抽象出调用者不需要关心的控件。
• 不允许表单处于无效状态。