在 perl 中读取和写入文件

    this
    is just
    an example.

假设上面是out.txt。我想读书out.txt并写入同一个文件。

    <Hi >
    <this>
    <is just>
    <an example.>

修改的out.txt。 我想在某些行的开头和结尾添加标签。 由于我将多次读取该文件，因此我无法每次都将其写入不同的文件。

EDIT 1我尝试使用"+<"但它给出这样的输出：

Hi
this
is just
an example.
<Hi >
<this>
<is just>
<an example.>
 **out.txt**

EDIT 2参考代码：

open(my $fh, "+<", "out.txt");# or die "cannot open < C:\Users\daanishs\workspace\CCoverage\out.txt: $!";
     while(<$fh>)
     {
        $s1 = "<";
        $s2 = $_;
        $s3 = ">";
        $str = $s1 . $s2 . $s3;
        print $fh "$str";
     }

你想要做的事情的想法本身就是有缺陷的。文件开头为

H  i  /  t  h  i  s  /  ...

如果您要就地更改它，则在处理第一行后它将如下所示：

<  H  i  >  /  i  s  /  ...

注意到你是如何破坏“th”的吗？您需要制作文件的副本，修改副本，然后用副本替换原始文件。

最简单的方法是在内存中制作此副本。

my $file;
{ # Read the file
   open(my $fh, '<', $qfn)
      or die "Can't open \"$qfn\": $!\n";
   local $/;
   $file = <$fh>;
}

# Change the file
$file =~ s/^(.*)\n/<$1>\n/mg;

{ # Save the changes
   open(my $fh, '>', $qfn)
      or die "Can't create \"$qfn\": $!\n";
   print($fh $file);
}

如果您想使用磁盘：

rename($qfn, "$qfn.old")
   or die "Can't rename \"$qfn\": $!\n";

open(my $fh_in, '<', "$qfn.old")
      or die "Can't open \"$qfn\": $!\n";
open(my $fh_out, '>', $qfn)
      or die "Can't create \"$qfn\": $!\n";

while (<$fh_in>) {
   chomp;
   $_ = "<$_>";
   print($fh_out "$_\n");
}

unlink("$qfn.old");

使用一个技巧，上面的内容可以简化为

local @ARGV = $qfn;
local $^I = '';
while (<>) {
   chomp;
   $_ = "<$_>";
   print(ARGV "$_\n");
}

或者作为一句单行：

perl -i -pe'$_ = "<$_>"' file