Excel VBA - 连接两个数组

我需要将两个数组 vd 和 vd1 连接到 vdu 中。

ReDim vdu(1 To (UBound(vd, 1) + UBound(vd1, 1)), 1 To 1)

For i = 1 To UBound(vd, 1)
   vdu(i, 1) = vd(i, 1)
Next i

For j = i To UBound(vdu, 1)
   vdu(j, 1) = vd1(j - i + 1, 1)
Next j

首先，我得到“超出范围”错误。

其次，最终我将需要加入 18 个数组，所以我不知道这是否是加入它们的最佳想法。

try with

    ReDim vdu(LBound(vd) To UBound(vd) + UBound(vd1), 1 To 1)

    For i = LBound(vdu) To UBound(vdu)
        If i <= UBound(vd) Then
            vdu(i, 1) = vd(i, 1)
        Else
            vdu(i, 1) = vd1(i - UBound(vd), 1)
        End If
    Next i

更新问题的第二部分我会将您的合并代码转换为函数

Public Function MergeArrays(arr1 As Variant, arr2 As Variant) As Variant
    Dim i As Long
    Dim arr As Variant
    ReDim arr(LBound(arr1, 1) To UBound(arr1, 1) + UBound(arr2, 1), 1 To 1)

    For i = LBound(arr, 1) To UBound(arr, 1)
        If i <= UBound(arr1, 1) Then
            arr(i, 1) = arr1(i, 1)
        Else
            arr(i, 1) = arr2(i - UBound(arr1, 1), 1)
        End If
    Next i
    MergeArrays = arr
End Function

然后一次将每个数组传递给它 1 个，例如

arr = MergeArrays(vd1, vd2)
arr = MergeArrays(arr, vd3)
arr = MergeArrays(arr, vdx)

您可以通过将数组存储在数组或字典中并循环遍历它来循环遍历它

其他选项

Public Function MergeArrays(ParamArray arrays() As Variant) As Variant
    Dim i As Long, j As Long, cnter As Long, UBoundArr As Long, OldUBoundArray As Long
    Dim arr() As Variant

    For j = LBound(arrays) To UBound(arrays)
        UBoundArr = UBoundArr + UBound(arrays(j), 1)
    Next j

    ReDim arr(1 To UBoundArr, 1 To 1)
    For j = LBound(arrays) To UBound(arrays)
        For i = LBound(arrays(j)) To UBound(arrays(j))
            arr(i + OldUBoundArray, 1) = arrays(j)(i, 1)
        Next i
        OldUBoundArray = OldUBoundArray + UBound(arrays(j), 1)
    Next j

    MergeArrays = arr
End Function

此方法使用 ParamArray。如果您不确定那是什么，请查找它，但实际上您可以将未指定数量的参数传递给该函数。因此，使用此函数，您可以组合任意数量的数组（具有相同形状和相同基数，即 x 到 x，1 到 1），并且它将组合它们。打电话就像

arr = MergeArrays(vd, vd1, vd2,....,vd18)