“暂停”具有属性的线程

我有一个 TThread 对象，希望能够通过程序主窗体上的按钮启动/停止线程。我一直在研究实现这一点的方法，到目前为止我有以下想法：

1. 当用户单击“停止”时终止并释放线程，并在单击“开始”时创建一个新线程。
2. 使用 sleep 来延迟线程（我不想这样做）
3. 有一个布尔值属性来确定线程是否暂停。仅当该布尔值为 false 时，执行中的代码才会发生。

我倾向于#3。从主窗体中设置 TThread 对象的布尔属性是否是线程安全的？

我应该选择这些选项中的哪一个或更好的选择？这是我第一次使用线程，因此非常感谢任何帮助。

1.当用户单击“停止”时终止并释放线程，并在单击“开始”时创建一个新线程。

如果开销很小，这当然是一个选择。

3.有一个布尔值属性来确定线程是否暂停。仅当该布尔值为 false 时，执行中的代码才会发生。

您可以这样做，但您必须定期检查该布尔值，如果设置，则进入等待循环，直到它被清除或线程收到终止信号。

从主窗体中设置 TThread 对象的布尔属性是否是线程安全的？

它与调用一样线程安全TThread.Terminate()，它只是设置布尔值TThread.Terminated财产。

我应该选择这些选项中的哪一个或更好的选择？

我使用选项 #4 - 使用有信号事件而不是布尔值。例如：

type
  TMyThread = class(TThread)
  private
    FRunEvent, FTermEvent: TEvent;
    FWaitEvents: THandleObjectArray;
    procedure CheckPause;
  protected
    procedure Execute; override;
    procedure TerminatedSet; override;
  public
    constructor Create; reintroduce;
    destructor Destroy; override;
    procedure Pause;
    procedure Unpause;
  end;

constructor TMyThread.Create;
begin
  inherited Create(False);

  FRunEvent := TEvent.Create(nil, True, True, '');
  FTermEvent := TEvent.Create(nil, True, False, '');

  SetLength(FWaitEvents, 2);
  FWaitEvents[0] := FRunEvent;
  FWaitEvents[1] := FTermEvent;
end;

destructor TMyThread.Destroy;
begin
  FRunEvent.Free;
  FTermEvent.Free;
  inherited;
end;

procedure TMyThread.Execute;
begin
  while not Terminated do
  begin
    // do some work...
    CheckPause;
    // do some more work...
    CheckPause;
    // do some more work...
    CheckPause;
    //...
  end;
end;

procedure TMyThread.TerminatedSet;
begin
  FTermEvent.SetEvent;
end;

procedure TMyThread.CheckPause;
var
  SignaledEvent: THandleObject;
begin
  while not Terminated do
  begin
    case TEvent.WaitForMultiple(FWaitEvents, INFINITE, False, SignaledEvent) of
      wrSignaled: begin
        if SignaledEvent = FRunEvent then Exit;
        Break;
      end;
      wrIOCompletion: begin
        // retry
      end;
      wrError: begin
        RaiseLastOSError;
    end;
  end;
  SysUtils.Abort;
end;

procedure TMyThread.Pause;
begin
  FRunEvent.ResetEvent;
end;

procedure TMyThread.Unpause;
begin
  FRunEvent.SetEvent;
end;