我如何从delphi检索WinInet错误代码的错误描述

我需要获取 WinInet 函数错误代码的描述，有关 WinInet 函数的 MSDN 文档说明了我必须使用GetLastError http://msdn.microsoft.com/en-us/library/ms679360%28VS.85%29.aspx函数在函数失败时检索最后一个错误代码。现在，当我检查有关的文档时GetLastError http://msdn.microsoft.com/en-us/library/ms679360%28VS.85%29.aspx函数说 .

.获取系统错误字符串 错误代码，使用格式化消息 http://msdn.microsoft.com/en-us/library/ms679351%28VS.85%29.aspx功能

我检查哪个SysErrorMessage http://docwiki.embarcadero.com/VCL/en/SysUtils.SysErrorMessagedelphi函数内部调用格式化消息 http://msdn.microsoft.com/en-us/library/ms679351%28VS.85%29.aspxwinapi 函数，所以我使用该函数来检索错误描述，但不起作用（我的意思是不返回 WinInet 错误代码的描述）我在 Delphi 2007 和 Delphi XE 中测试了此代码。

看这段代码

uses
  Wininet, Windows, SysUtils;


procedure  TestWinInet(const AUrl : string);
var
  hInter,hRemoteUrl : HINTERNET;
  Code : Cardinal;
begin

  hInter := InternetOpen(PChar('Explorer 5.0'), INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  if hInter=nil then
  begin
    Code:=GetLastError;
    raise Exception.Create(Format('Error %d Description %s',[Code,SysErrorMessage(Code)]));
  end;

  try
    hRemoteUrl := InternetOpenUrl(hInter, PChar(AUrl), nil, 0, INTERNET_FLAG_RELOAD, 0);
    if hRemoteUrl=nil then
    begin
      Code:=GetLastError;
      raise Exception.Create(Format('Error %d Description %s',[Code,SysErrorMessage(Code)]));
    end;

    try
      //do something  else


    finally
     InternetCloseHandle(hRemoteUrl);
    end;
  finally
    InternetCloseHandle(hInter);
  end;
end;

begin
  try
      //i am passing a invalid url just to raise the error
     TestWinInet('Foo');
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

当我执行此代码时，返回代码 12006，其定义为ERROR_INTERNET_UNRECOGNIZED_SCHEME http://support.microsoft.com/kb/193625和相关的描述是The URL scheme could not be recognized or is not supported.

所以问题是How I can retrieve the error description for the WinInet error codes in delphi?

我认为你应该尝试直接使用FormatMessage，因为你需要知道错误代码的来源。我找到了这个工作代码。

class function TCertificateManager.GetLastErrorText: string;
var
  code: DWORD;
  Len: Integer;
  Buffer: array[0..255] of Char;
begin
  code := GetLastError();
  Len := FormatMessage(FORMAT_MESSAGE_FROM_HMODULE or FORMAT_MESSAGE_FROM_SYSTEM,
  Pointer(GetModuleHandle('Advapi32.dll')), code, 0, Buffer, SizeOf(Buffer), nil);
  while (Len > 0) and (Buffer[Len - 1] in [#0..#32, '.']) do Dec(Len);
  SetString(Result, Buffer, Len);
end;

您应该进行一些更改，可能使用“wininet.dll”而不是 Advapi32.dll，但它应该可以工作。

UPDATE

这是 WinInet 函数的版本

function GetWinInetError(ErrorCode:Cardinal): string;
const
   winetdll = 'wininet.dll';
var
  Len: Integer;
  Buffer: PChar;
begin
  Len := FormatMessage(
  FORMAT_MESSAGE_FROM_HMODULE or FORMAT_MESSAGE_FROM_SYSTEM or
  FORMAT_MESSAGE_ALLOCATE_BUFFER or FORMAT_MESSAGE_IGNORE_INSERTS or  FORMAT_MESSAGE_ARGUMENT_ARRAY,
  Pointer(GetModuleHandle(winetdll)), ErrorCode, 0, @Buffer, SizeOf(Buffer), nil);
  try
    while (Len > 0) and {$IFDEF UNICODE}(CharInSet(Buffer[Len - 1], [#0..#32, '.'])) {$ELSE}(Buffer[Len - 1] in [#0..#32, '.']) {$ENDIF} do Dec(Len);
    SetString(Result, Buffer, Len);
  finally
    LocalFree(HLOCAL(Buffer));
  end;
end;