使用RTL布局时如何通过命中测试获取树视图项？

描述：

在从右到左阅读模式（RTL）下有树视图，如何在仅知道单击坐标的情况下获取被单击的节点？这是一个插入类，它使树视图使用 RTL 显示，并包含一个单击处理程序，您可以在其中看到问题：

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, CommCtrl;

type
  TTreeView = class(ComCtrls.TTreeView)
  protected
    procedure CNNotify(var Msg: TWMNotify); message CN_NOTIFY;
    procedure CreateParams(var Params: TCreateParams); override;
  end;

type
  TForm1 = class(TForm)
    TreeView1: TTreeView;
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TTreeView }

procedure TTreeView.CNNotify(var Msg: TWMNotify);
var
  Node: TTreeNode;
  Point: TPoint;
begin
  inherited;
  if Msg.NMHdr.code = NM_CLICK then
  begin
    Point := ScreenToClient(Mouse.CursorPos);
    Node := GetNodeAt(Point.X, Point.Y);
    if Assigned(Node) then
      ShowMessage('This message never shows...');
  end;
end;

procedure TTreeView.CreateParams(var Params: TCreateParams);
begin
  inherited CreateParams(Params);
  Params.Style := Params.Style or TVS_RTLREADING;
  Params.ExStyle := Params.ExStyle or WS_EX_LAYOUTRTL or WS_EX_RIGHT;
end;

{ TForm1 }    

procedure TForm1.FormCreate(Sender: TObject);
var
  Node: TTreeNode;
begin
  Node := TreeView1.Items.AddChild(nil, 'Item 1');
  TreeView1.Items.AddChild(Node, 'SubItem 1');
end;

end.

这段代码的问题（或者更好地说是 RTL 模式下的树视图）是，当您单击节点（或任何位置）时，GetNodeAt http://docwiki.embarcadero.com/Libraries/XE3/en/Vcl.ComCtrls.TCustomTreeView.GetNodeAt方法永远不会返回有效节点（总是nil）。对于那些没有 Delphi 的人来说GetNodeAt http://docwiki.embarcadero.com/Libraries/XE3/en/Vcl.ComCtrls.TCustomTreeView.GetNodeAt方法内部调用TreeView_HitTest http://msdn.microsoft.com/en-us/library/windows/desktop/bb773897%28v=vs.85%29.aspx当树视图处于 RTL 模式时，返回的宏NULL就像不会有任何物品一样。我将通过以下方式获得的坐标传递给该宏GetCursorPos http://msdn.microsoft.com/en-us/library/windows/desktop/ms648390%28v=vs.85%29.aspx相对于控制计算的函数ScreenToClient http://msdn.microsoft.com/en-us/library/windows/desktop/dd162952%28v=vs.85%29.aspx功能。

问题：

我的问题是，如何让单击的节点只知道鼠标坐标？如何在RTL模式下使用树视图进行命中测试？例如，我是否应该从右侧计算鼠标水平位置，如果是，如何计算？

From ScreenToClient http://msdn.microsoft.com/en-us/library/windows/desktop/dd162952%28v=vs.85%29.aspx文档：

不使用屏幕到客户端当处于镜像情况时，即当 从左到右布局更改为从右到左布局。反而， 使用MapWindowPoints http://msdn.microsoft.com/en-us/library/windows/desktop/dd145046%28v=vs.85%29.aspx。有关详细信息，请参阅“窗口布局和 窗口功能中的“镜像”。

更正后的代码可能类似于：

  ..
  Point := Mouse.CursorPos;
  MapWindowPoints(0, Handle, Point, 1);
  Node := GetNodeAt(Point.X, Point.Y);
  ..

另请参阅：窗口布局和镜像 http://msdn.microsoft.com/en-us/library/windows/desktop/ms632599%28v=vs.85%29.aspx#layout_mirroring