使用用户窗体中的数据将值从一张纸复制到另一张纸

我有一个用户表单，其中包含您可以填写的以下值：

TextBoxLopnummer.Value
TextBoxFragestallare.Value
TextBoxMottagare.Value
TextBoxDatum.Value

Picture:

当有人填写日期值时：TextBoxDatum.Value我想在整个工作簿中搜索该值，并将该单元格所在的整行粘贴到工作表“Lägg in ärende”单元格 A15 内。请注意，该值可以位于工作簿中的不同工作表中，并且可以在同一工作表内多次出现。因此，在单元格 A15 及以下单元格中可以有很多行。

我已经开始实施这一点，但老实说我不知道​​如何完成它：

'in the rows below I wanna write so that ".Value=copies the value from the sheets where it finds eg. the date".
emptyRow = WorksheetFunction.CountA(ws.Range("A:A")) + 14
Cells(emptyRow, 1).Value =
Cells(emptyRow, 2).Value =
Cells(emptyRow, 3).Value =
Cells(emptyRow, 4).Value =
Cells(emptyRow, 5).Value =
Cells(emptyRow, 6).Value =
Cells(emptyRow, 7).Value =
Cells(emptyRow, 8).Value =

请注意，您可以同时搜索多个日期，您可以根据 4 个条件进行搜索，请参见上图。当您填写 2 个条件时，代码应将这两个条件与整个工作簿中具有相同条件的行进行匹配，并复制该行等。

此外，TextBoxLopnummer 将始终位于单元格 A2 中，并在其被搜索的工作表中向下。TextBoxFragestallare 位于单元格 B2 中，TextBoxMottagare 位于单元格 C2 中，TextBoxDatum 位于单元格 D2 中。

我怎样才能继续解决我的问题？

这将使您大部分完成您想要做的事情。根据您原来问题中的评论，我相信这就是您所需要的。

Process:

• 在用户窗体代码上为搜索按钮添加一个单击事件。在示例中，它是 Button1。根据自己的需要命名。

• 每次运行前清除目标表（每个请求）

• 从文本框值设置一个数组，其中每个值的索引与要搜索的列号匹配

• 循环遍历每个工作表（目标工作表除外）。

• 一次一行，将相应列的值与与其匹配的数组索引进行比较。

• 如果找到匹配项，则“match”变量设置为 true

• 循环遍历数组中的其余文本框值，如果其中任何一个不匹配，则“match”变量设置为 false，并以失败的方式中断对文本框的循环。

• 如果在搜索工作表的 ROW 循环结束时“match”为 true，则循环遍历第 1 至 8 列，将搜索工作表中的值设置为目标工作表。

• 下一行完成循环

• 下一个工作表完成循环

可能要检查的问题：

• 您可能需要对日期进行一些转换，但如果工作表上的日期与用户表单上的日期格式相同，那么它应该可以工作。

• 如果工作表中的文本具有 0.0 或不同的小数位，则数字可能会出现类似的问题。

• 如果发生任何此类问题，只需使用本地窗口并逐步执行代码以查看其执行情况。您收到的类似错误可能是类型不匹配。通过使用“本地”窗口进行调试，您将知道哪些特定值需要格式化才能与文本框进行比较。如果单步执行时间太长，请设置断点。

未经测试：有问题评论。

Private Sub button1_click()

Dim ws As Worksheet
Dim lastRow As Long, lRow As Long, tRow As Long
Dim tempValue As String
Dim targetSheet As String
Dim tempList(1 To 4) As String
Dim i As Long
Dim match As Boolean

match = False

'Set TargetSheet and clear the previous contents
targetSheet = "Lägg in Ärende"
tRow = 15
lastRow = Sheets(targetSheet).Range("A" & Rows.count).End(xlUp).row
Sheets(targetSheet).Range("A15:H" & lastRow).ClearContents

'Set an array of strings, based on the index matching the column to search for each
tempList(1) = TextBoxLopnummer.Text       'Column "A" (1)
tempList(2) = TextBoxFragestallare.Text   'Column "B" (2)
tempList(3) = TextBoxMottagare.Text       'Column "C" (3)
tempList(4) = TextBoxDatum.Text           'Column "D" (4)

    'Search through each worksheet
    For Each ws In Worksheets
        If ws.name <> targetSheet Then
            'Get last row of sheet
            lastRow = ws.Range("A" & Rows.count).End(xlUp).row

            'Search through the sheet
            For lRow = 2 To lastRow
                'Using the array of values from the TextBoxes,
                'Each column number matches the index of the array.
                'Only testing the array values that have text in them,
                'If any don't match the loop is broken and returns to main search.
                For i = 1 To 4
                    If tempList(i) <> "" Then
                        If ws.Cells(lRow, i).Text = tempList(i) Then
                            match = True
                        Else
                            match = False
                            Exit For        'If any of the values is false, exit i loop
                        End If
                    End If
                Next i

                'If there was a match, copy the data from Searched ws to targetSheet
                If match = True Then
                    'Get the first Empty row on target sheet
                    For lCol = 1 To 8
                        Sheets(targetSheet).Cells(tRow, lCol).Value = ws.Cells(lRow, lCol).Value
                    Next lCol
                    tRow = tRow + 1
                End If
            Next lRow
        End If
    Next ws

End Sub