将 C 字符串数组传递给 Fortran (iso_c_binding)

如何传递 C 字符串数组（char* cstrings[]) 到 Fortran 子程序？

问题使用 iso_c_binding 的 fortran-C 桥接器中的字符串数组 https://stackoverflow.com/questions/9686532肯定是相关的，但答案似乎不正确，甚至不能用 GNU Fortran 编译。

我目前正在为 Fortran 代码开发 C 接口，我期望iso_c_binding（我以前用过）会让这变得小菜一碟。到目前为止，C 字符串数组还没有运气......

Fortran 子例程应采用字符串数组作为参数。 在普通的 Fortran 语言中，我会写如下内容：

subroutine print_fstring_array(fstring)

  implicit none

  character(len=*), dimension(:), intent(in) :: fstring
  integer                                    :: i

  do i = 1, size(fstring)
    write(*,*) trim(fstring(i))
  end do

end subroutine print_fstring_array

将单个 C 字符串传递给 Fortran 的一种方法是作为 C 指针 (c_ptr）（我知道，我也可以使用一系列character(kind=c_char))

subroutine print_cstring(cstring) bind(C)

  use iso_c_binding, only: c_ptr, c_f_pointer, c_loc, c_null_char
  implicit none

  type(c_ptr), target, intent(in) :: cstring
  character(len=1024), pointer    :: fstring
  integer                         :: slen

  call c_f_pointer(c_loc(cstring), fstring)
  slen = index(fstring, c_null_char) - 1
  write(*,*) fstring(1:slen)

end subroutine print_cstring

所以，我假设了一个数组c_ptr是个好主意

subroutine print_cstring_array(n, cstring) bind(C)

  use iso_c_binding, only: c_ptr, c_int, c_f_pointer, c_loc, c_null_char
  implicit none

  integer(kind=c_int),               intent(in) :: n
  type(c_ptr), dimension(n), target, intent(in) :: cstring
  character(len=1024), pointer                  :: fstr
  integer                                       :: slen, i

  do i = 1, n
    call c_f_pointer(c_loc(cstring(i)), fstring)
    slen = index(fstring, c_null_char) - 1
    write(*,*) fstring(1:slen)
  end do

end subroutine print_cstring_array

但这会产生分段错误。

最后一个示例的 C 代码是

# include "stdio.h"
# include "fstring.h"

void main(void) {
  char* cstring[] = { "abc", "def", "ghi", "jkl" };
  int n = 4;
  print_cstring_array(&n, cstring);
}

以及头文件的内容fstring.h很简单：

void print_cstring_array(int* n, char* cstring[]);

我的目标是 GNU Fortran 和 Intel Fortran，并已使用 GNU Fortran 测试了上述内容。这字符串的长度是固定的（上例中的 3），以防这简化了解决方案。然而，数组的维度可以变化。

任何指针（甚至 C 指针）都将不胜感激。

问题中代码中最大的问题是您使用c_f_pointer(c_loc(cstring),代替c_f_pointer(cstring,.

这对我有用：

subroutine print_cstring_array(n, cstring) bind(C)

  use iso_c_binding, only: c_ptr, c_int, c_f_pointer, c_loc, c_null_char
  implicit none

  integer(kind=c_int),               intent(in) :: n
  type(c_ptr), dimension(n), target, intent(in) :: cstring
  character, pointer                            :: fstring(:)
  integer                                       :: slen, i

  do i = 1, n
    call c_f_pointer(cstring(i), fstring, [4])
    write(*,*) fstring
  end do

end subroutine print_cstring_array



# include "stdio.h"

void print_cstring_array(int* n, char* cstring[]);

void main(void) {
  char* cstring[] = { "abc", "def", "ghi", "jkl" };
  int n = 4;
  print_cstring_array(&n, cstring);
}