在 Perl 中使用引用指向滑动窗口数组

这是我的问题：我有 2 个数组。一种是字符数组，代表滑动窗口。角色从开头移动并推到结尾。我想使用第二个数组来存储对数组切片的引用，这些数组切片“跟随”字符移动。例子：

my @char_array = ('h','e','l','l','o','w','o','r','l','d');
my $char_arr_ref=[@char_array[1..$#char_array]]; 
print @$char_arr_ref, "\n"; # slice contains 'elloworld';
shift(@char_array);
push(@char_array), 'x';
print @$char_arr_ref, "\n"; # slice still contains 'elloworld', not 'lloworldx' as I need;

换句话说，我希望能够使用第二个数组来引用数组切片（例如，就像我对 C 中的指针数组所做的那样）。

在 Perl 中是否有一种惯用的方法可以做到这一点？

更新：这是一个更大的程序的一部分，用于快速文本搜索。我打算使用引用的散列（例如，而不是慢得要命的“索引”函数。我需要在 Perl 中执行此操作。

在 C 中，您的窗口可能是使用指针算术来实现的。

const char* s = str+1;
const char* e = str+len;
for (const char* p=s; p!=e; ++p) putc(*p);

除了指针算术不允许您调整缓冲区的大小（push @char_array, 'x';）。即使在 C 语言中，您也必须使用偏移量。

size_t si = 1;
size_t ei = len;
for (size_t i=si; i!=e1; ++i) putc(str[i]);

这是幸运的，因为 Perl 没有指针，更不用说指针运算了。但抵消呢？没问题！

my @char_array = split //, 'helloworld';
my ($s, $e) = (1, $#char_array);
say @char_array[$s..$e];    # elloworld
shift @char_array;
push @char_array, 'x';
say @char_array[$s..$e];    # lloworldx

如果我们实际上讨论的是字符，那么字符串会更有效。

my $char_array = 'helloworld';
my ($s, $e) = (1, length($char_array));
say substr($char_array, $s, $e-$s+1);    # elloworld
$char_array =~ s/^.//s;
$char_array .= 'x';
say substr($char_array, $s, $e-$s+1);    # lloworldx

事实上，如果我们实际上谈论的是字符，我们非常幸运，因为我们可以使用左值 substr 并让 Perl 为我们处理偏移量！

my $char_array = 'helloworld';
my $substr_ref = \substr($char_array, 1, length($char_array)-1);
say $$substr_ref;        # elloworld
$char_array =~ s/^.//s;
$char_array .= 'x';
say $$substr_ref;        # lloworldx

比 C 更容易，并且具有或多或少相同的好处！