Emacs 邪恶模式：如何创建一个新的文本对象来选择带有任何非空格字符的单词？

我正在尝试在 Evil 中创建一个新的文本对象。例如，文本对象iw只会选择包含连字符的字符串子集。我希望新的文本对象能够将单词与任何非空格字符相匹配。到目前为止我得到的是：

(evil-define-text-object evil-inner-space (count &optional beg end type)
  "Select inner space."
  :extend-selection nil
  (evil-regexp-range count beg end type "[ \n]" " " t))

(define-key evil-inner-text-objects-map " " 'evil-inner-space)

此代码无法正确匹配行尾的单词。由于 \n，它适用于行首的单词。

我尝试了很多方法都行不通。对我来说，麻烦在于，当某些东西不起作用时，我不知道这是由于错误的正则表达式还是由于邪恶正则表达式范围的限制。例如，使用 \s- 会报告错误，这似乎是 Evil 中的限制。

Update: evil-regexp-range最近被替换为evil-select-paren https://bitbucket.org/lyro/evil/issue/454/evil-regexp-range-was-recently-removed。这适用于当前的邪恶，并且与旧的用法相同：

(defmacro define-and-bind-text-object (key start-regex end-regex)
  (let ((inner-name (make-symbol "inner-name"))
        (outer-name (make-symbol "outer-name")))
    `(progn
       (evil-define-text-object ,inner-name (count &optional beg end type)
         (evil-select-paren ,start-regex ,end-regex beg end type count nil))
       (evil-define-text-object ,outer-name (count &optional beg end type)
         (evil-select-paren ,start-regex ,end-regex beg end type count t))
       (define-key evil-inner-text-objects-map ,key (quote ,inner-name))
       (define-key evil-outer-text-objects-map ,key (quote ,outer-name)))))

原答案：

如果您最终定义了多个新文本对象，则重复可能会变得烦人，尤其是当您想要绑定内部和外部对象时。如果您遇到了这个障碍，请尝试以下操作：

(defmacro define-and-bind-text-object (key start-regex end-regex)
  (let ((inner-name (make-symbol "inner-name"))
        (outer-name (make-symbol "outer-name")))
    `(progn
      (evil-define-text-object ,inner-name (count &optional beg end type)
        (evil-regexp-range count beg end type ,start-regex ,end-regex t))
      (evil-define-text-object ,outer-name (count &optional beg end type)
        (evil-regexp-range count beg end type ,start-regex ,end-regex nil))
      (define-key evil-inner-text-objects-map ,key (quote ,inner-name))
      (define-key evil-outer-text-objects-map ,key (quote ,outer-name)))))

Usage:

; between dollar signs:
(define-and-bind-text-object "$" "\\$" "\\$")

; between pipe characters:
(define-and-bind-text-object "|" "|" "|")

; from regex "b" up to regex "c", bound to k (invoke with "vik" or "vak"):
(define-and-bind-text-object "k" "b" "c")

（这超出了你想要的，但我会把它留在这里，以防它对某人有帮助:)