缺少 Haskell 原语来连续将函数应用于列表的每个元素？

在 Haskell 中，众所周知map原语可用于将给定函数应用于all列表的元素：

 λ> map toUpper "abcd"
"ABCD"
 λ> 

在尝试生成有限集（列表）的所有分区时，以下类似的原语会很方便：

 λ> sap toUpper "abcd"
["Abcd","aBcd","abCd","abcD"]
 λ> 

with sap代表连续申请。 类型签名将是：

sap :: (a -> a) -> [a] -> [[a]]

例如，集合“abcd”的部分分区可以通过使用('a':) sap'ing从“bcd”的分区中获得。

 λ> pbcd = [["b","c","d"],["b","cd"],["bc","d"],["c","bd"],["bcd"]]
 λ> 
 λ> concatMap (sap ('a':)) pbcd
[["ab","c","d"],["b","ac","d"],["b","c","ad"],["ab","cd"],["b","acd"],["abc","d"],["bc","ad"],["ac","bd"],["c","abd"],["abcd"]]
 λ> 

然后可以通过添加“a”作为其自己的单独单例来获得 5 个丢失的分区。

我的问题是我无法在语言库中找到这样的原语，并且Hoogle https://hoogle.haskell.org/给定类型签名，不会返回任何感兴趣的内容。

是否有这样的原语sap存在于 Haskell 语言库中的某个地方？？？ 或者有没有一种方法可以编写得如此简短，以至于它甚至不值得成为一个单独的函数，将其放在所谓的下面费尔贝恩阈值 https://wiki.haskell.org/Fairbairn_threshold ?

Footnote: 可以写sap像这样：

sap :: (a -> a) -> [a] -> [[a]]
sap fn ls = fst  $  foldr  op  ([], [])  ls
   where  op x (ll,tl) = ( ((fn x):tl) : map (x:) ll , x:tl )

本质上你从[[fn (last ls)]]作为种子，然后向左前进。但这行人似乎并不简单。

看起来最简单的版本是直接递归：

sap :: (a -> a) -> [a] -> [[a]]
sap _ [] = []
sap f (x:xs) = (f x : xs) : map (x:) (sap f xs)

对此的一种可能的探索是作为拟态现象 https://hackage.haskell.org/package/recursion-schemes-5.1.3/docs/Data-Functor-Foldable.html#v:para，它可以同时访问递归结果和未处理的余数。

sap f = para step where
    step Nil = []
    step (Cons x (xs, rest)) = (f x : xs) : map (x:) rest

（未检查，可能有愚蠢的错误）

但我并不认为这是一个巨大的进步。我没有从问题本身的递归分解中看到任何深刻的见解。

为此，嗯...我用过holesOf https://hackage.haskell.org/package/lens-4.18.1/docs/Control-Lens-Traversal.html#v:holesOf过去的通用版本。

sap :: Traversable t => (a -> a) -> t a -> [t a]
sap f = map (peeks f) . holesOf traverse

现在这肯定是说某物。它概括了适用于所有实例的类型Traversable。另一方面，所涉及的理论块对于最终结果来说是如此强大，以至于我不确定它到底说了什么。在第三（？）手上，它看起来很漂亮。