gnuplot 动画 2D 矢量场

我正在尝试使用 gnuplot 制作 2D 矢量动画。我想显示一行，即一次显示一个向量。

我的数据结构如下：它们x，y，u，v

2.24448 0.270645    1.00    1.00
3.24448 0.270645    0.500   1.20

我可以使用以下命令创建静态图：

plot "datam.dat" using 1:2:3:4 with vectors filled head lw 3

Here is the output:

这是我的问题：我想制作动画并显示一行（即）一次矢量，如何使用 GIF 在 GNU 绘图中实现这一点？

Thanks

动画 GIF 的创建方式是set terminal gif animate. Check help gif了解详情。 下面是一个简单的示例（使用 gnuplot 5.2 测试）。您必须为每一帧制作一个新的绘图。所以，将你的绘图命令放入do for-环形。和every ::i::i你只绘制i第 行（检查help every）。如果您不知道数据文件的总行数，请执行以下操作stats "YourFile.dat"和变量STATS_records会告诉你这个数字。

Code:

### animated graph with vectors
reset session

set term gif size 300,300 animate delay 12 loop 0 optimize
set output "AnimateVectors.gif"

# create some dummy data
set angle degrees
N = 60
set samples N
set table $Data
    plot [0:360] '+' u (cos($1)):(sin($1)):(sin($1)):(cos($1)) w table
unset table

set xrange[-2.5:2.5]
set yrange[-2.5:2.5]
do for [i=0:N-1] {
    plot $Data u 1:2:3:4 every ::i::i w vectors lw 2 lc rgb "red" notitle
}
set output
### end of code

Result:

添加：

这将是非动画版本，例如在一个wxt-终端。

Code:

### non-animated graph with vectors
reset session
set term wxt size 400,400

# create some dummy data
set angle degrees
N = 60
set samples N
set table $Data
    plot [0:360] '+' u (cos($1)):(sin($1)):(sin($1)):(cos($1)) w table
unset table

set xrange[-2.5:2.5]
set yrange[-2.5:2.5]
plot $Data u 1:2:3:4 w vectors lw 1.5 lc rgb "red" notitle
### end of code

Result:

加法2：

你的意思可能是这样的吗？ “半”动画箭头？顺便说一下，正如你所看到的，箭头看起来很不同gif and wxt终端。

Code:

### "semi"-animated graph with vectors
reset session
set term gif size 300,300 animate delay 12 loop 0 optimize
set output "AnimateVectorsSemi.gif"

# create some dummy data
set angle degrees
N = 60
set samples N
set table $Data
    plot [0:360] '+' u (cos($1)):(sin($1)):(sin($1)):(cos($1)) w table
unset table

set xrange[-2.5:2.5]
set yrange[-2.5:2.5]

do for [i=0:N-1] {
    plot $Data u 1:2:3:4 every ::0::i w vectors lw 1.5 lc rgb "red" notitle
}
set output
### end of code

Result: