如何使用AWK从文件中连续输出行

我有一个多行文件，我想连续输出文件的某些行，比如第一次，从第1行打印到第5行，下次，打印第2行到第6行，依此类推。 我发现 AWK 是一个非常有用的函数，我尝试自己编写代码，但它什么也没输出。 以下是我的代码

#!/bin/bash
for n in `seq 1 3`
do
  N1=$n
  N2=$((n+4))
  awk -v n1="$N1" -v n2="$N2" 'NR == n1, NR == n2 {print $0}' my_file >> new_file
done

例如，我有一个名为 my_file 的输入文件

1 99 tut
2 24 bcc
3 32 los
4 33 rts
5 642 pac
6 23 caas
7 231 cdos
8 1 caee
9 78 cdsa

然后我期望输出文件为

1 99 tut
2 24 bcc
3 32 los
4 33 rts
5 642 pac
2 24 bcc
3 32 los
4 33 rts
5 642 pac
6 23 caas
3 32 los
4 33 rts
5 642 pac
6 23 caas
7 231 cdos

您能否尝试按照 GNU 中所示的示例进行编写和测试awk。需要提及需要打印的所有行的地方lines_from变量，那么有一个变量名为till_lines它告诉我们需要从特定行打印多少行（例如-->从第一行打印接下来的 4 行）。另一方面，我已经测试了OP的代码，它对我来说工作得很好，它自调用以来使用 new_file 生成输出文件awk在 bash 循环中并不是一个好的做法，因此在这里也将其添加为改进。

awk -v lines_from="1,2,3" -v till_lines="4" '
BEGIN{
  num=split(lines_from,arr,",")
  for(i=1;i<=num;i++){ line[arr[i]] }
}
FNR==NR{
  value[FNR]=$0
  next
}
(FNR in line){
  print value[FNR] > "output_file"
  j=""
  while(++j<=till_lines){ print value[FNR+j] > "output_file" }
}
'  Input_file  Input_file

当我看到内容时output_file我可以看到以下内容：

cat output_file
1 99 tut
2 24 bcc
3 32 los
4 33 rts
5 642 pac
2 24 bcc
3 32 los
4 33 rts
5 642 pac
6 23 caas
3 32 los
4 33 rts
5 642 pac
6 23 caas
7 231 cdos

解释：对上述内容添加详细解释。

awk -v lines_from="1,2,3" -v till_lines="4" '    ##Starting awk program from here and creating 2 variables lines_from and till_lines here, where lines_from will have all line numbers which one wants to print from. till_lines is the value till lines one has to print.
BEGIN{                                           ##Starting BEGIN section of this program from here.
  num=split(lines_from,arr,",")                  ##Splitting lines_from into arr with delimiter of , here.
  for(i=1;i<=num;i++){                           ##Running a for loop from i=1 to till value of num here.
    line[arr[i]]                                 ##Creating array line with index of value of array arr with index of i here.
  }
}
FNR==NR{                                         ##Checking condition FNR==NR which will be TRUE when 1st time Input_file is being read.
  value[FNR]=$0                                  ##Creating value with index as FNR and its value is current line.
  next                                           ##next will skip all further statements from here.
}
(FNR in line){                                   ##Checking condition if current line number is coming in array then do following.
  print value[FNR] > "output_file"               ##Printing value with index of FNR into output_file
  j=""                                           ##Nullifying value of j here.
  while(++j<=till_lines){                        ##Running while loop from j=1 to till value of till_lines here.
    print value[FNR+j] > "output_file"           ##Printing value of array value with index of FNR+j and print output into output_file
  }
}
'  Input_file Input_file                         ##Mentioning Input_file names here.