Excel VBA application.visible 立即设置回 True

我已经设置了一个新的、空的、无模式的用户表单，用最少的代码来解决我的问题。

当工作簿打开时，执行以下代码来隐藏 Excel 并显示用户窗体。这是工作簿的唯一代码。

Private Sub Workbook_Open()
    UserForm1.Show
    If Application.Windows.Count <> 1 Then
        Application.Windows("test.xlsm").Visible = False
    Else
        Application.Visible = False
    End If
End Sub

我有一个空的用户表单，只有一个按钮。该用户表单的唯一代码是：

Private Sub CommandButton1_Click()
    Application.Windows("test.xlsm").Visible = True
    Application.Visible = True
Unload Me
End Sub

最后一件事是第一个工作表上的按钮，用于启动与打开工作簿时相同的过程。其代码：

Sub Button1_Click()
    UserForm1.Show
    If Application.Windows.Count <> 1 Then
        Application.Windows("test.xlsm").Visible = False
    Else
        Application.Visible = False
    End If
End Sub

现在我的问题是： 当我打开工作簿时，用户窗体会显示，但 Excel 和活动窗口也保持可见。但是，如果我单击工作表上的按钮，Excel 或窗口将按其应有的方式隐藏。此外，在加载所有内容后，Excel（而不是用户窗体）获得焦点。

我第一次运行这个，效果很好。我怀疑更改编辑器中的 ShowModal 设置以某种方式搞砸了，但这只是我的猜测。无论如何，无论现在的模式设置如何，它都不再按预期工作。

如果我只是跑

Application.Visible = False

Excel 仍然保持可见，而不是“if”子句，当然活动窗口也是可见的。

这让我抓狂。 我缺少什么？

编辑：链接到我的测试文件：我的 Dropbox 上的测试文件 https://www.dropbox.com/s/2jz52956valr0yi/test.xlsm?dl=0可能需要启动两次，因为当宏在启动时被阻止并且仅在 Excel 完全加载后才激活时，代码将按预期工作。

编辑：我能够在 Excel 2010 电脑上对此进行测试，并且问题不存在。因此，这可能与较新的 Office 应用程序处理内容的方式有关。

我发现自己遇到了完全相同的问题 - 用以下命令打开的无模式表单Workbook_Open()事件也应该隐藏 Excel 应用程序（适用于 Excel 2016，32 位）。

与它合作的原因UserForm财产显示模态 set to True是因为：执行被暂停 - 它正在等待用户与显示的用户窗体进行交互。 https://stackoverflow.com/a/1784410

如果我们改变显示模态 to False（或致电UserForm.Show vbModeless）那么执行就永远不会暂停，一旦我们到达End Sub of our Workbook_Open(), Excel 似乎设置Application.Visible = True在其自己的。

到目前为止我找到的唯一解决方案是this one https://stackoverflow.com/a/43765665- 基本上是你suspend通过添加无限循环来执行，以便 Excel 仅在您摆脱（卸载/隐藏）先前显示的表单后才结束此事件。

我的版本如下所示：

Private Sub Workbook_Open()
    Dim App As Object
    Set App = startMenu

    App.Show vbModeless

    While App.Visible
        DoEvents
    Wend
End Sub

然后只是为了确保 Excel 在无模式后关闭UserForm已关闭我添加了以下内容：

Private Sub UserForm_Terminate()
    CloseApp
End Sub

Public Sub CloseApp()
    ThisWorkbook.Saved = True

    If Not OtherWorkbooksOpen Then
        Application.Quit
    Else
        ThisWorkbook.Close
    End If
End Sub

Public Function OtherWorkbooksOpen()
    If Application.Workbooks.Count > 1 Then
        OtherWorkbooksOpen = True
    Else
        OtherWorkbooksOpen = False
    End If
End Function

EDIT:

没有无限循环的解决方案 https://stackoverflow.com/a/25040582- Excel 的时间表隐藏：

Private Sub Workbook_Open()
    Dim App As Object
    Set App = startMenu

    App.Show
    If Not OtherWorkbooksOpen Then
        Application.OnTime Now + TimeValue("00:00:01"), "HideExcel"
    End If
End Sub