使用 VBA 在另一个 Access 实例中打开特定窗体

所以我在这里四处查看并找不到我的问题的答案。至少不完全是。

案例如下：

我在 DBase1 中，想要单击一个按钮并在单独的访问实例中打开 DBase2 中的 NeuSteckbrief 表单。

我设法使用以下代码在单独的实例中打开 DBase2：

 Private Sub SteckbriefDB_Click()

 Dim dq As String
 Dim strExe As String
 Dim strMdb As String
 Dim strRun As String
 Dim dblReturnVal As Double

 dq = """"

 'Define var strExe; Miscosoft Access
 strExe = "C:\Program Files (x86)\Microsoft Office\Office14\MSACCESS.EXE"

 'Define var strMdb; Steckbrief database location
 strMdb = "Correct Path\SteckbriefDB.accdb"

 'Define the entire statement to implement at Shell
 strRun = dq & strExe & dq & " " & dq & strMdb & dq

 'Run the code to open the project database
 dblReturnVal = Shell(strRun, vbMaximizedFocus)


End Sub

我的问题是在刚刚打开的数据库中打开 NeuSteckbrief 表单。我尝试添加 DoCmd.OpenForm "NeuSteckbrief", acNormal 但这不起作用。

您知道如何以打开数据库和正确形式的方式调整我的代码吗？

你应该really使用 OLE 自动化来做这样的事情：

Private Sub SteckbriefDB_Click()
 Dim strMdb As String
 'Define var strMdb; Steckbrief database location
 strMdb = "Correct Path\SteckbriefDB.accdb"
 Dim appSecondInstance As New Access.Application
 With appSecondInstance
    .Visible = True
    .UserControl = True
    .OpenCurrentDatabase strMdb
    .DoCmd.OpenForm "NeuSteckbrief", acNormal
 End With
End Sub