如何将 JSON 字符串转换为图像？

我有一个将图像转换为 JSON 数组的应用程序，并将其保存到 blob 字段中：

function getImage(): String;
var
  memorystream : TMemoryStream;
  jsonArray    : TJSONArray;

begin
  memorystream := TMemoryStream.Create;
  myImage.Picture.Graphic.SaveToStream(memorystream);
  memorystream.Position := 0;

  jsonArray := TJSONArray.Create;
  jsonArray := TDBXJSONTools.StreamToJSON(memorystream, 0, memorystream.Size);

  memorystream.Free;

  Result := jsonArray.ToString;
end;

PNG 图像的转换结果如下所示：

[137,80,78,71,13,10,26,10,0,0, ... ]

这个结果存储在一个 blob 字段中，我用以下代码返回该字段：

stream := TStream.Create;
stream := cdsPesquisa.CreateBlobStream(fieldAux, bmRead);
stream.Position := 0;

jsonArray := TJSONArray.Create;
jsonArray := TDBXJSONTools.StreamToJSON(stream, 0, stream.Size);

在这里，我有相同的 JSON 字符串[137,80,78,71,13,10,26,10,0,0, ... ]一开始，但我需要再次将这个 JSON 数组转换为图像。

我怎样才能做到这一点？

正如 Ken 所建议的，最简单的方法是忘记 JSON 并直接写入 blob 字段。

Saving

Stream := TMemoryStream.Create;
try
  myImage.Picture.Graphic.SaveToStream(Stream);
  Stream.Position := 0;
  fieldAux.LoadFromStream(Stream);
finally
  Stream.Free;
end;

Loading

Stream := TMemoryStream.Create;
try
  fieldAux.SaveToStream(Stream);
  Stream.Position := 0;
  myImage.Picture.Graphic.LoadFromStream(Stream);
finally
  Stream.Free;
end;

您在评论中似乎坚持认为 JSON 就是您所需要的。我觉得有点难以置信。但无论如何，要将保存在字符串中的 JSON 数组转换为图像，请执行以下操作：

jsonArray := TJSONObject.ParseJSONValue(jsonString) as TJSONArray;
try
  Stream := TDBXJSONTools.JSONToStream(jsonArray);
  try
    Stream.Position := 0;
    myImage.Picture.Graphic.LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
finally
  jsonArray.Free;
end;

另外，据我所知，您的代码调用TDBXJSONTools.StreamToJSON不起作用。它生成一个空的 JSON 数组对象。

最后，你的代码像筛子一样泄漏了。您误认为不需要释放您创建的对象。您还错误地实例化对象，然后用不同的对象覆盖新对象，从而泄漏第一个对象。看一下我如何创建对象，并与您的代码进行比较。例如：

jsonArray := TJSONArray.Create ;
jsonArray := TDBXJSONTools.StreamToJSON( memorystream , 0 , memorystream.Size ) ;

在这里你实例化一个TJSONArray对象并将对该对象的引用存储在jsonArray。释放该引用是您的工作。但是，当您使用对返回的新对象的引用覆盖它时，您会立即放弃下一行中的该引用StreamToJSON。既然你从来没有自由过jsonArray无论如何，你泄漏的不是一个，而是两个对象。

您确实需要温习对 Delphi 生命周期管理的基本了解。