如何在 Perl 中生成数组的所有排列？

生成所有内容的最佳（优雅、简单、高效）方式是什么？n!perl 中数组的排列？

例如，如果我有一个数组@arr = (0, 1, 2)，我想输出所有排列：

0 1 2
0 2 1
1 0 2
1 2 0
2 0 1
2 1 0

它可能应该是一个返回迭代器的函数（惰性/延迟评估，因为n!可以变得如此大），所以可以这样调用：

my @arr = (0, 1, 2);
my $iter = getPermIter(@arr);
while (my @perm = $iter->next() ){
    print "@perm\n";
}

From perlfaq4 http://faq.perl.org/perlfaq4.html: “如何排列列表中的 N 个元素？” http://learn.perl.org/faq/perlfaq4.html#How-do-I-permute-N-elements-of-a-list:

在 CPAN 上使用 List::Permutor 模块。如果列表实际上是一个数组，请尝试 Algorithm::Permute 模块（也在 CPAN 上）。它是用 XS 代码编写的，非常高效：

use Algorithm::Permute;

my @array = 'a'..'d';
my $p_iterator = Algorithm::Permute->new ( \@array );

while (my @perm = $p_iterator->next) {
   print "next permutation: (@perm)\n";
}

为了更快地执行，您可以这样做：

use Algorithm::Permute;

my @array = 'a'..'d';

Algorithm::Permute::permute {
    print "next permutation: (@array)\n";
} @array;

这是一个小程序，它生成每行输入上所有单词的所有排列。 Knuth 的《计算机编程艺术》第 4 卷（尚未出版）中讨论了 permute() 函数中体现的算法，并且适用于任何列表：

#!/usr/bin/perl -n
# Fischer-Krause ordered permutation generator

sub permute (&@) {
    my $code = shift;
    my @idx = 0..$#_;
    while ( $code->(@_[@idx]) ) {
        my $p = $#idx;
        --$p while $idx[$p-1] > $idx[$p];
        my $q = $p or return;
        push @idx, reverse splice @idx, $p;
        ++$q while $idx[$p-1] > $idx[$q];
        @idx[$p-1,$q]=@idx[$q,$p-1];
    }
}


permute { print "@_\n" } split;

Algorithm::Loops 模块还提供 NextPermute 和 NextPermuteNum 函数，它们可以有效地查找数组的所有唯一排列，即使它包含重复值，也可以就地修改它：如果其元素按反向排序，则数组将被反转，使其排序，并返回 false；否则返回下一个排列。

NextPermute 使用字符串顺序和 NextPermuteNum 数字顺序，因此您可以像这样枚举 0..9 的所有排列：

use Algorithm::Loops qw(NextPermuteNum);

my @list= 0..9;
do { print "@list\n" } while NextPermuteNum @list;