我在哪里可以学习高级 Haskell？ [关闭]

在评论中我的答案之一 https://stackoverflow.com/questions/4633584/algorithm-to-generate-all-possible-arrays-of-ones-and-zeros-of-a-given-length/4633658#4633658，SO用户sdcwc本质上指出了以下代码：

comb 0 = [[]]

comb n =
    let rest = comb (n-1)
    in  map ('0':) rest
     ++ map ('1':) rest

可以替换为：

comb n = replicateM n "01"

这让我完全惊呆了。

现在我正在寻找教授这些高级概念的教程、书籍或 PDF。我是not寻找针对初学者的“什么是 monad”教程或解释 monad 类型的在线参考资料replicateM。我想学习如何用单子思考并有效地使用它们，如果你愿意的话，单子“模式”。

采取类似的功能sequence, filterM, liftM2, join并思考它们如何为每个单子发挥作用IO, [], (->) a, Writer, State。例如，sequencefor IO monad 顺序执行 IO 操作：

 [IO a] -> IO [a]

写下签名并尝试使用它们。有些组合很有趣，有些则不那么有趣。

过滤器示例：

{-# LANGUAGE NoMonomorphismRestriction #-}
import Control.Monad
import Control.Monad.State
import Control.Monad.Reader

a = filterM (\x -> do putStrLn $ "Put " ++ show x ++ "?"
                      fmap (=="Y") getLine)

b = filterM (const [False,True])

c m xs = runState (filterM k xs) 0
              where k x = do a <- get
                             let p = a + x <= m
                             when p $ put (a+x)
                             return p

d = filterM (flip id)

a使用 IO 过滤列表 - 它向用户询问每个项目。

b不确定地过滤列表 - 每个项目都不确定地包含和不包含。结果，你得到了 powerset。 （尝试一下！）

c过滤列表，维护状态。在这种情况下，这是贪婪的背包 - 你有容量的背包m并想要插入尽可能多的项目xs.

d过滤列表，保持只读状态。这并不有趣。我使用过滤函数作为状态，这给出了flip filter.

单一功能filterM可以做所有这些事情。

如果您为其他函数编写类似的代码，您将有足够的直觉来注意到其他地方的一元函数。例如，如何获得以下函数？

dup f x = f x x

那么呢dup' f x = f x x x?