Flex&Bison 简单入门

• Ref: 《flex与bison(中文版)》

1. Flex&Bison安装

1. 安装flex

sudo apt install flex

1. 安装bison

sudo apt install bison

1. 安装gcc(若缺少)

sudo apt-get install -y build-essential

2. Flex&Bison使用

2.1 第一个flex程序

1. Flex程序 例1-1: 字数统计 fb1-1.l

/* 正如Unix的wc程序 */
%{
int chars = 0;
int words = 0;
int lines = 0;
%}
%%
[a-zA-Z]+    { words++; chars += strlen(yytext); }
\n           { chars++; lines++; }
.            { chars++; }
%%

main(int argc, char **argv) {
    yylex();
    printf("%8d%8d%8d\n", lines, words, chars);
}

1. 运行程序:

$ flex fb1-1.l    # 使用flex翻译程序
$ cc lex.yy.c -lfl    # 编译程序, 与flex库文件链接
$ ./a.out
The boy stood on the burining deck
shelling peanuts by the peck
^D
       2      12      63

• 注: ^D是Unix/Linux文件结束符, 此处用于结束输入

1. 运行截图
   

2.2 Flex&Bison协同工作

1. Flex程序1

例1-3: 一个简单的flex词法分析器 fb1-3.l

1. 代码:

/* 识别出用于计数器的记号并把它们输出 */
%%
"+"    { printf("PLUS\n"); }
"-"    { printf("MINUS\n"); }
"*"    { printf("TIMES\n"); }
"/"    { printf("DIVIDE\n"); }
"|"    { printf("ABS\n"); }
[0-9]+ { printf("NUMBER %s\n", yytext); }
\n     { printf("NEWLINE\n"); }
[ \t]  { }
.      { printf("Mystery character %s\n", yytext); }
%%

1. 运行程序:
   

2. Flex程序2

例1-4: 计算器词法分析器 fb1-4.l

1. 代码:

/* 识别出用于计数器的记号并把它们输出 */
%{
    enum yytokentype {
        NUMBER = 258,
        ADD = 259,
        SUB = 260,
        MUL = 261,
        DIV = 262,
        ABS = 263,
        EOL = 264
    };
    int yylval;
%}

%%
"+"    { return ADD; }
"-"    { return SUB; }
"*"    { return MUL; }
"/"    { return DIV; }
"|"    { return ABS; }
[0-9]+ { yylval = atoi(yytext); return NUMBER; }
\n     { return EOL; }
[ \t]  { /* 忽略空白字符*/ }
.      { printf("Mystery character %c\n", *yytext); }
%%
main(int argc, char **argv) {
    int tok;
    while(tok = yylex()) {
        printf("%d", tok);
        if(tok == NUMBER) printf(" = %d\n", yylval);
        else printf("\n");
    }
}

1. 运行程序:
   

3. 简单的计算器程序

1. Bison代码:
   例1-5: 简单的计算器 fb1-5.y

/* 计算器的最简版本 */
%{
#include <stdio.h>
%}
%token NUMBER
%token ADD SUB MUL DIV ABS
%token EOL

%%

calclist: /* 空规则 */
    | calclist exp EOL { printf("= %d\n", $2); }
    ;

exp: factor { $$ = $1; }
    | exp ADD factor { $$ = $1 + $3; }
    | exp SUB factor { $$ = $1 - $3; }
    ;

factor: term { $$ = $1; }
    | factor MUL term { $$ = $1 * $3; }
    | factor DIV term { $$ = $1 / $3; }
    ;

term: NUMBER { $$ = $1; }
    | ABS term { $$ = $2 >= 0? $2 : -$2; }
    ;
%%
main(int argc, char **argv) {
    yyparse();
}
yyerror(char* s) {
    fprintf(stderr, "error: %s\n", s);
}

• 注: 书上代码有误, 上已修正

1. Flex代码:
   例1-6: 计算器词法分析器 fb1-5.l

%{
#include "fb1-5.tab.h"
%}
%%
"+"    { return ADD; }
"-"    { return SUB; }
"*"    { return MUL; }
"/"    { return DIV; }
"|"    { return ABS; }
[0-9]+ { yylval = atoi(yytext); return NUMBER; }
\n     { return EOL; }
[ \t]  { /* 忽略空白字符*/ }
.      { printf("Mystery character %c\n", *yytext); }

1. 编译的Makefile:

fb1-5: fb1-5.l fb1-5.y
    bison -d fb1-5.y    # 运行bison, 创建fb1-5.tab.c和 fb1-5.tab.h
    flex fb1-5.l    # 运行flex, 创建lex.yy.c
    cc -o $@ fb1-5.tab.c lex.yy.c -lfl

1. 进行编译

$ make

• 遇到问题: Makefile:2: *** 遗漏分隔符 (null)。 停止。
  解决: Makefile文件中, 缩进是TAB分隔符, 不能是空格
• 遇到问题:
• 
  
  解决: 见上#1代码
  编译信息:
  

1. 运行结果: