我的 Fortran 95 随机数生成器有什么问题吗？

这是一个随机数生成器模块，我用它与我的主程序一起编译（此处未列出） 当我尝试编译随机数生成器模块以查看其是否有效时，我收到以下消息：

第 61 行：调用 random_seed( put = Seed) 错误：“random_seed”内在函数的“put”参数大小太小

这是什么意思？我该如何修复它？

module random_angle
 contains
 0
    integer Function random_integer (N)         ! return a random integer between 1 and N
        integer, intent(in) :: N
        real*8 :: x

        call random_number(x)
        random_integer = floor(real(N)*x)+1

    end function random_integer

    Real*8 Function gasdev()           !  ch7.pg.280:gaussian distribution function using ran1 as random # generator

        implicit none
!       integer, intent(inout) :: idum
        integer, save::iset
        real*8:: fac,rsq,v1,v2
        real*8, dimension(2) :: x
        real*8, save :: gset

!       if (idum.lt.0) iset=0
        if (iset.eq.0) then
          rsq = 0.0
          do while (rsq > 1.0.or.rsq==0)  
            call random_number(x)
            v1=2.*x(1)-1
            v2=2.*x(2)-1
            rsq=v1**2+v2**2
!    print *, v1, v2,rsq
          end do    

          fac=sqrt(-2.*log(rsq)/rsq)
          gset=v1*fac
          gasdev=v2*fac
          iset=1
        else
            gasdev=gset
            iset=0
        endif

        return

    end Function gasdev

    real*8 function NormalRandom (average, stddev)
        implicit none
        real*8, intent(in):: average, stddev
        NormalRandom = average + stddev*gasdev()

    end function NormalRandom

    subroutine setSEED (seed)
        implicit none

        real*8:: x
        integer, dimension(4), intent(inout):: seed
        if (seed(1) == 0.0) &
            seed = floor(1000*secnds(0.0)) +(/0, 37, 74, 111 /)  
        call random_seed( put=seed)

    end subroutine setSEED

end module random_angle

当编译器说

错误：“random_seed”内在函数的“put”参数大小太小

这意味着你的变量的大小seed太小。

在这种情况下你有seed大小为 4（我猜编译器肯定期望（至少）为 12）。

数组的大小必须具有一定的大小，这取决于编译器。您可以通过调用来确定所需的大小random_seed与另一个论点

integer seed_size
integer, allocatable :: seed(:)

call random_seed(size=seed_size)
allocate(seed(seed_size))
seed = ...
call random_seed(put=seed)

正如 Vladimir F 在评论中指出的那样，gfortran 文档本身有一个例子这种方法。

如果您不关心可移植性，则可以仅使用大小为 12 的数组以及您选择的值。

作为更高级的阅读，我会说另一件事。我上面给出的示例确实与您的代码不太可比。也就是说，您说种子设置子例程的输入保证大小至少为 4，并且它可能包含也可能不包含您想要用作种子的值。

正如我上面提到的，您可以将其更改为 12，但这不可移植。如果你想便携，事情就会变得更加尴尬。

integer, dimension(4), intent(inout):: seed

有一个大小为 4 的显式形状数组作为虚拟参数。主程序中的实际参数是一个至少具有该大小的数组。然而，这个尺寸是一个规范表达而且，唉，call random_seed(size=seed_size)没有给我们一些可以在规范表达式中使用的东西。

也许像

subroutine setSEED (seed)
  integer, allocatable, intent(inout) :: seed(:)
  integer seed_size

  ! Determine the correct size for the seed
  call random_seed(size=seed_size)

  ! If our seed isn't set, or is too small, kill it.
  if (ALLOCATED(seed)) then
    if (SIZE(seed)<seed_size.or.seed(LBOUND(seed,1))==0.) deallocate(seed)
  end if

  ! If seed isn't allocated (perhaps we killed it because it was too small)
  ! then allocate it to the correct size and initialize it.
  if (.not.ALLOCATED(seed)) then
    allocate(seed(seed_size))
    seed = ...  ! Our fallback seed initialization
  end if

  ! Finally, put the seed.  Using one we set, or the one originally given.
  call random_seed(put=seed)

end subroutine

当然，这要求实际论证是allocatable，但如果您正在处理便携式播种机，那是一件好事。