拖动对象时启用其他事件

我正在开发一个控制台，我想将按钮拖动到网格中：

要拖动按钮，我使用以下过程：

Public drag As Boolean = False
Public ptX As Integer = 0
Public ptY As Integer = 0
Public btn As Button

Private Sub MoveButton_MouseDown(sender As Object, e As MouseEventArgs) Handles MoveButton.MouseDown
    drag = True
    btn = CType(sender, Button)
    ptX = e.X : ptY = e.Y
End Sub

Private Sub MoveButton_MouseMove(sender As Object, e As MouseEventArgs) Handles MoveButton.MouseMove
    If drag Then
        btn.Location = New Point(btn.Location.X + e.X - ptX, btn.Location.Y + e.Y - ptY)
        Me.Refresh()
    End If
End Sub

Private Sub MoveButton_MouseUp(sender As Object, e As MouseEventArgs) Handles MoveButton.MouseUp
    drag = False
End Sub

到目前为止，一切都很好！这对于此事来说效果很好。 但是，我试图在将按钮悬停在单元格上时突出显示该单元格，如下所示：

为此，我尝试执行以下操作：

Private Sub CellA1_MouseHover(sender As Object, e As EventArgs) Handles CellA1.MouseHover
    If drag Then
        CellA1.BackColor = Color.Red
    End If
End Sub

当然我不能这样做，除非我以某种方式启用CellA1.MouseHover拖动时发生的事件MoveButton.

谁能帮我这个？

但是，如果您不愿意进一步帮助我，我的最后一个目标就是让MoveButton在红细胞位置：

但请随意不要帮助我完成这部分过程，因为我还没有代码来执行此操作。 任何帮助将不胜感激。一如既往，提前感谢大家。

由于您的鼠标实际上并未位于PictureBox当您拖动按钮时，它永远不会引发任何鼠标事件。你可以做的是调用GetChildAtPoint() method您的表单以获得控制权behind按钮。完成后，只需验证名称是否以“Cell”开头并更改背景颜色即可。

要捕捉到单元格的位置，您需要指出MouseUp我们目前在哪个牢房。只需将单元格控件存储在变量中，然后您就可以设置yourButton.Location = currentCell.Location

以下是我对您的代码所做的更改，为了清楚起见，进行了注释：

Public drag As Boolean = False
Public ptX As Integer = 0
Public ptY As Integer = 0
Public btn As Button
Public prevCtrl As Control = Nothing 'Store the previous Cell the button was dragged over.
'                                     We need this to be able to reset the BackColor of the Cell, 
'                                     and also so that you can snap to its location once you drop the button.

Private Sub MoveButton_MouseDown(sender As Object, e As MouseEventArgs) Handles MoveButton.MouseDown
    'No changes made here.
    drag = True
    btn = CType(sender, Button)
    ptX = e.X : ptY = e.Y
End Sub

Private Sub MoveButton_MouseMove(sender As Object, e As MouseEventArgs) Handles MoveButton.MouseMove
    If drag Then
        btn.Location = New Point(btn.Location.X + e.X - ptX, btn.Location.Y + e.Y - ptY)

        'Go 1 pixel up, or else GetChildAtPoint() will return the button instead of the control behind it.
        Dim LookPoint As Point = Point.Subtract(btn.Location, New Size(0, 1))

        'Get the control located below/behind the button.
        Dim ControlBelow As Control = Me.GetChildAtPoint(LookPoint, GetChildAtPointSkip.Invisible Or GetChildAtPointSkip.Disabled) 'Ignore invisible or disabled controls.

        'Check so that the previous cell is not also the current cell. If they're the same then we won't change anything.
        If prevCtrl IsNot ControlBelow Then

            'Ok, the current cell and the previous cell are not the same.
            'Now check if there was any previous cell at all.
            If prevCtrl IsNot Nothing Then
                'There was a previous cell, but since the button 
                'is no longer hovering over it we reset its BackColor.
                prevCtrl.BackColor = Color.White
                prevCtrl = Nothing
            End If

            'Check that there infact is a control behind the button,
            'and also check that its name starts with "Cell".
            If ControlBelow IsNot Nothing AndAlso ControlBelow.Name.StartsWith("Cell", StringComparison.OrdinalIgnoreCase) Then
                'The control behind the button is a valid Cell. Change its BackColor.
                ControlBelow.BackColor = Color.Red
                prevCtrl = ControlBelow 'The previous cell is now the current cell.
            End If

        End If

        'Me.Refresh() - this is a very unnecessary call, it will just eat CPU. The form does not need to be redrawn at this point.
    End If
End Sub

Private Sub MoveButton_MouseUp(sender As Object, e As MouseEventArgs) Handles MoveButton.MouseUp
    'Check if we dragged the button. At this point prevCtrl is the current cell (if it's not Nothing).
    If drag = True AndAlso prevCtrl IsNot Nothing Then
        btn.Location = prevCtrl.Location 'Snap to the cell's location.
        prevCtrl.BackColor = Color.White 'Reset the cell's BackColor.
        prevCtrl = Nothing 'Reset this since we're no longer dragging the button.
    End If

    drag = False
End Sub

它就像一个魅力！