ANTLR：有一个简单的例子吗？

我想开始使用 ANTLR，但是在花了几个小时查看了示例之后antlr.org http://www.antlr.org/网站上，我仍然无法清楚地了解Java的语法过程。

有没有一些简单的例子，比如用 ANTLR 实现的四操作计算器，遍历解析器定义并一直到 Java 源代码？

Note: 这个答案是为了ANTLR3！如果您正在寻找ANTLR4例如，那么这个演示如何创建一个简单的表达式解析器和评估器ANTLR4.

您首先创建一个语法。下面是一个小语法，您可以使用它来计算使用 4 个基本数学运算符构建的表达式：+、-、* 和 /。您还可以使用括号对表达式进行分组。

请注意，此语法只是一个非常基本的语法：它不处理一元运算符（-1+9 中的减号）或像 0.99 这样的小数（没有前导数字），仅举两个缺点。这只是一个示例，您可以自己操作。

这是语法文件的内容Exp.g:

grammar Exp;

/* This will be the entry point of our parser. */
eval
    :    additionExp
    ;

/* Addition and subtraction have the lowest precedence. */
additionExp
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

/* Multiplication and division have a higher precedence. */
multiplyExp
    :    atomExp
         ( '*' atomExp 
         | '/' atomExp
         )* 
    ;

/* An expression atom is the smallest part of an expression: a number. Or 
   when we encounter parenthesis, we're making a recursive call back to the
   rule 'additionExp'. As you can see, an 'atomExp' has the highest precedence. */
atomExp
    :    Number
    |    '(' additionExp ')'
    ;

/* A number: can be an integer value, or a decimal value */
Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

/* We're going to ignore all white space characters */
WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

（解析器规则以小写字母开头，词法分析器规则以大写字母开头）

创建语法后，您需要从中生成解析器和词法分析器。下载ANTLR罐子 http://www.antlr.org/download/antlr-3.2.jar并将其存储在与语法文件相同的目录中。

在 shell/命令提示符下执行以下命令：

java -cp antlr-3.2.jar org.antlr.Tool Exp.g

它不应该产生任何错误消息，并且文件ExpLexer.java, ExpParser.java and 经验代币现在应该已生成。

要查看是否一切正常，请创建此测试类：

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
        ExpLexer lexer = new ExpLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        ExpParser parser = new ExpParser(tokens);
        parser.eval();
    }
}

并编译它：

// *nix/MacOS
javac -cp .:antlr-3.2.jar ANTLRDemo.java

// Windows
javac -cp .;antlr-3.2.jar ANTLRDemo.java

然后运行它：

// *nix/MacOS
java -cp .:antlr-3.2.jar ANTLRDemo

// Windows
java -cp .;antlr-3.2.jar ANTLRDemo

如果一切顺利，控制台上不会打印任何内容。这意味着解析器没有发现任何错误。当你改变时"12*(5-6)" into "12*(5-6"然后重新编译并运行它，应该打印以下内容：

line 0:-1 mismatched input '<EOF>' expecting ')'

好的，现在我们想在语法中添加一些 Java 代码，以便解析器真正执行一些有用的操作。添加代码可以通过放置来完成{ and }在你的语法里面有一些简单的Java代码。

但首先：语法文件中的所有解析器规则都应返回原始双精度值。您可以通过添加来做到这一点returns [double value]每条规则之后：

grammar Exp;

eval returns [double value]
    :    additionExp
    ;

additionExp returns [double value]
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

// ...

这几乎不需要解释：每个规则都应该返回一个双精度值。现在与返回值“交互”double value（它不在纯 Java 代码块内{...}）从代码块内部，您需要在前面添加一个美元符号value:

grammar Exp;

/* This will be the entry point of our parser. */
eval returns [double value]                                                  
    :    additionExp { /* plain code block! */ System.out.println("value equals: "+$value); }
    ;

// ...

这是语法，但现在添加了 Java 代码：

grammar Exp;

eval returns [double value]
    :    exp=additionExp {$value = $exp.value;}
    ;

additionExp returns [double value]
    :    m1=multiplyExp       {$value =  $m1.value;} 
         ( '+' m2=multiplyExp {$value += $m2.value;} 
         | '-' m2=multiplyExp {$value -= $m2.value;}
         )* 
    ;

multiplyExp returns [double value]
    :    a1=atomExp       {$value =  $a1.value;}
         ( '*' a2=atomExp {$value *= $a2.value;} 
         | '/' a2=atomExp {$value /= $a2.value;}
         )* 
    ;

atomExp returns [double value]
    :    n=Number                {$value = Double.parseDouble($n.text);}
    |    '(' exp=additionExp ')' {$value = $exp.value;}
    ;

Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

自从我们的eval规则现在返回一个双精度值，将 ANTLRDemo.java 更改为：

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
        ExpLexer lexer = new ExpLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        ExpParser parser = new ExpParser(tokens);
        System.out.println(parser.eval()); // print the value
    }
}

再次（重新）从语法生成新的词法分析器和解析器 (1)，编译所有类 (2) 并运行 ANTLRDemo (3)：

// *nix/MacOS
java -cp antlr-3.2.jar org.antlr.Tool Exp.g   // 1
javac -cp .:antlr-3.2.jar ANTLRDemo.java      // 2
java -cp .:antlr-3.2.jar ANTLRDemo            // 3

// Windows
java -cp antlr-3.2.jar org.antlr.Tool Exp.g   // 1
javac -cp .;antlr-3.2.jar ANTLRDemo.java      // 2
java -cp .;antlr-3.2.jar ANTLRDemo            // 3

现在您将看到表达式的结果12*(5-6)打印到你的控制台！

再次强调：这是一个非常简短的解释。我鼓励您浏览ANTLR 维基 http://www.antlr.org/wiki/display/ANTLR3/ANTLR+3+Wiki+Home并阅读一些教程和/或玩一下我刚刚发布的内容。

祝你好运！

EDIT:

这个帖子 https://stackoverflow.com/questions/2042353/extending-simple-antlr-grammer-to-support-input-variables展示了如何扩展上面的示例，以便Map<String, Double>可以提供在所提供的表达式中保存变量。

为了让此代码与当前版本的 Antlr（2014 年 6 月）一起使用，我需要进行一些更改。ANTLRStringStream需要成为ANTLRInputStream，返回值需要更改为parser.eval() to parser.eval().value，我需要删除WS子句放在最后，因为属性值如$channel不再允许出现在词法分析器操作中。