尽管最终确定，Fortran 派生类型数组和内存泄漏

尽管我已经编写了最终的过程，但我定义了一个派生类型并遇到了一些内存释放问题。代码如下

module ModuleCoordinate
  implicit none

  type :: TCoordinate
    real(8),dimension(:),pointer :: Coordinate => NULL()
    contains
      procedure :: TCoordinateAssignment
      generic,public :: Assignment(=) => TCoordinateAssignment
      final :: TCoordinateDel
  end type TCoordinate

  interface TCoordinate
    module procedure :: TCoordinateInit
  end interface TCoordinate

  contains
    subroutine TCoordinateDel(self)
      type(TCoordinate),intent(inout) :: self
      if(associated(self%Coordinate))deallocate(self%Coordinate)
    end subroutine TCoordinateDel

    subroutine TCoordinateAssignment(O1,O2)
      class(TCoordinate),intent(out) :: O1
      type(TCoordinate),intent(in) :: O2
      if(associated(O2%Coordinate))allocate(O1%Coordinate,source=O2%Coordinate)
    end subroutine TCoordinateAssignment

    type(TCoordinate) function TCoordinateInit(IVal1,IVal2) result(self)
      real(8),intent(in) :: IVal1,IVal2
      allocate(self%Coordinate(2))
      self%Coordinate=(/IVal1,IVal2/)
    end function TCoordinateInit
end module ModuleCoordinate

测试代码如下

program test
  implicit none
  integer(4),parameter :: NLoop=40000
  integer(4) :: i
  do i=1,NLoop
    call TestMemory1()
    call TestMemory2()
  end do
  pause
end program test

subroutine TestMemory1()
  use ModuleCoordinate
  implicit none
  integer(4),parameter :: DN=10
  integer(4) :: i
  type(TCoordinate),dimension(DN) :: a
  do i=1,DN
    a(i)=TCoordinate(1.0_8,1.0_8)
  end do
end subroutine TestMemory1

subroutine TestMemory2()
  use ModuleCoordinate
  implicit none
  type(TCoordinate) :: b1,b2,b3,b4,b5,b6,b7,b8,b9,b10
  b1=TCoordinate(1.0_8,1.0_8)
  b2=TCoordinate(1.0_8,1.0_8)
  b3=TCoordinate(1.0_8,1.0_8)
  b4=TCoordinate(1.0_8,1.0_8)
  b5=TCoordinate(1.0_8,1.0_8)
  b6=TCoordinate(1.0_8,1.0_8)
  b7=TCoordinate(1.0_8,1.0_8)
  b8=TCoordinate(1.0_8,1.0_8)
  b9=TCoordinate(1.0_8,1.0_8)
  b10=TCoordinate(1.0_8,1.0_8)
end subroutine TestMemory2

事实证明，子程序TestMemory2可以，同时TestMemory1不是，这意味着当声明此派生类型的数组时，最终过程不起作用并且内存泄漏。

但是，如果我删除=> NULL()在右边Coordinate在这个派生类型的定义中，两个子例程似乎都运行良好。

当指针指向时有什么区别Coordinate正在被解除分配吗？如果重要的话，编译器是 ifort_2013_sp1.3.174 。

在终结过程的描述中我们看到（Fortran 2008, 4.5.6.2）

如果实体的动态类型具有最终子例程，其虚拟参数具有与正在最终确定的实体相同的类型类型参数和等级，则以该实体作为实际参数来调用它。否则，如果存在一个基本的最终子例程，其虚拟参数具有相同的值 kind 类型参数作为被最终确定的实体，以该实体作为实际参数来调用。否则，此时不会调用任何子例程。

有一个仅为标量（等级 0）实体提供的派生类型的最终子例程。要最终确定您的 1 级实体，最简单的方法（在本例中似乎）是使您拥有的子例程成为元素。

我有点不愿意提及=>NULL()方面，因为我目前没有方法来测试我要写的内容，但我会推测。

如果没有=>NULL()默认初始化指针组件具有未定义的关联状态。这意味着，当你这样做时

    b1=TCoordinate(1.0_8,1.0_8)

有趣的事情发生了。

作为作业的一部分b1在进入时最终确定TCoordinateAssignment。最终确定涉及调用associated与未定义关联状态的指针。这是不允许的（因此可能会出现任何结果）。