将数据上传到共享内存中用于卷积核

我在理解评论中提到的批量加载时遇到一些困难。为了计算像素中的卷积，大小为 5 的掩模必须以该特定像素为中心。图像被分成图块。应用卷积掩模后的这些图块是最终输出图块，其大小为TILE_WIDTH*TILE_WIDTH。对于属于输出图块边界的像素，当该图块属于图像的边界时，掩模必须从相邻图块借用一些像素。否则，这些借用值将被分配为零。这两个步骤描述于

if (srcY >= 0 && srcY < height && srcX >= 0 && srcX < width)
    N_ds[destY][destX] = I[src];
else
    N_ds[destY][destX] = 0;

因此，共享内存阵列具有TILE_WIDTH + Mask_width - 1每边的尺寸。我不清楚代码的以下部分。

1. The destY and destX指数。 将输出索引除以输入图块宽度意味着什么？

2. The srcY add srcX index.
   Why destY and destX指数参与srcY add srcX index?

   srcY = blockIdx.y * TILE_WIDTH + destY - Mask_radius;
   srcX = blockIdx.x * TILE_WIDTH + destX - Mask_radius;
   

3. 为什么在第二次加载时我们使用偏移量TILE_WIDTH * TILE_WIDTH?

4. 一般来说，有两个载荷的直观解释是什么？

5. 所有这些问题都可以根据下图给出一个直观的例子吗？

6. 谢谢你！

EDIT:图像已添加。绿色是输出图块，红色是以 114 索引为中心的掩码。很明显，面具借用了不同图块的元素。 最后，该图像指的是一个通道。

Example:根据下图，我尝试编写一个示例。输出图块有blockIdx.x=1 and blockIdx.y=1基于此destY=0 and destX=0. Also,
srcY = 1*6+0-3=3, srcX = 3 and src = (3*18+3)*3+0=171。根据计算和图像示例，我们没有匹配项。在第一个共享内存位置，应该存储的值是具有全局索引的值57。上述计算有什么问题呢？有人可以帮忙吗？

#define Mask_width  5
#define Mask_radius Mask_width/2
#define TILE_WIDTH 16
#define w (TILE_WIDTH + Mask_width - 1)
#define clamp(x) (min(max((x), 0.0), 1.0))

__global__ void convolution(float *I, const float* __restrict__ M, float *P,
                            int channels, int width, int height) {
   __shared__ float N_ds[w][w];
   int k;
   for (k = 0; k < channels; k++) {
      // First batch loading
      int dest = threadIdx.y * TILE_WIDTH + threadIdx.x,
         destY = dest / w, destX = dest % w,
         srcY = blockIdx.y * TILE_WIDTH + destY - Mask_radius,
         srcX = blockIdx.x * TILE_WIDTH + destX - Mask_radius,
         src = (srcY * width + srcX) * channels + k;
      if (srcY >= 0 && srcY < height && srcX >= 0 && srcX < width)
         N_ds[destY][destX] = I[src];
      else
         N_ds[destY][destX] = 0;

      // Second batch loading
      dest = threadIdx.y * TILE_WIDTH + threadIdx.x + TILE_WIDTH * TILE_WIDTH;
      destY = dest / w, destX = dest % w;
      srcY = blockIdx.y * TILE_WIDTH + destY - Mask_radius;
      srcX = blockIdx.x * TILE_WIDTH + destX - Mask_radius;
      src = (srcY * width + srcX) * channels + k;
      if (destY < w) {
         if (srcY >= 0 && srcY < height && srcX >= 0 && srcX < width)
            N_ds[destY][destX] = I[src];
         else
            N_ds[destY][destX] = 0;
      }
      __syncthreads();

      float accum = 0;
      int y, x;
      for (y = 0; y < Mask_width; y++)
         for (x = 0; x < Mask_width; x++)
            accum += N_ds[threadIdx.y + y][threadIdx.x + x] * M[y * Mask_width + x];
      y = blockIdx.y * TILE_WIDTH + threadIdx.y;
      x = blockIdx.x * TILE_WIDTH + threadIdx.x;
      if (y < height && x < width)
         P[(y * width + x) * channels + k] = clamp(accum);
      __syncthreads();
   }
}

您的问题在概念上与我在 StackOverflow 上的第一个问题类似：移动 (BS_X+1)(BS_Y+1) BS_X 的全局内存矩阵BS_Y 线程 https://stackoverflow.com/questions/13771538/moving-a-bs-x1bs-y1-global-memory-matrix-by-bs-xbs-y-threads.

您面临以下问题：每个线程块的大小TILE_WIDTHxTILE_WIDTH应该填充大小的共享内存区域(TILE_WIDTH + Mask_width - 1)x(TILE_WIDTH + Mask_width - 1).

4）一般来说，有两个载荷的直观解释是什么？

由于共享内存区域(TILE_WIDTH + Mask_width - 1)x(TILE_WIDTH + Mask_width - 1)大于块大小TILE_WIDTHxTILE_WIDTH并假设它小于2xTILE_WIDTHxTILE_WIDTH，那么每个线程最多应将两个元素从全局内存移动到共享内存。这就是为什么要进行两阶段加载的原因。

1) The destY and destX指数。将输出索引除以输入图块宽度意味着什么？

这涉及指定加载的第一个加载阶段TILE_WIDTHxTILE_WIDTH来自全局内存的元素并填充共享内存区域的最上部。

所以，操作

dest = threadIdx.y * TILE_WIDTH + threadIdx.x;

展平通用线程的 2D 坐标，同时

destX = dest % w;
destY = dest / w; 

进行逆操作，因为它计算通用线程相对于共享内存区域的 2D 坐标。

2) The srcY add srcX指数。为什么destY and destX指数参与srcY add srcX index?

srcY = blockIdx.y * TILE_WIDTH + destY - Mask_radius;

srcX = blockIdx.x * TILE_WIDTH + destX - Mask_radius;

(blockIdx.x * TILE_WIDTH, blockIdx.y * TILE_WIDTH)如果块大小和共享内存大小相同，则为全局内存位置的坐标。由于您还从相邻图块“借用”内存值，因此您必须将上述坐标移动(destX - Mask_radius, destY - Mask_radius).

3）为什么在第二次加载时我们使用偏移量TILE_WIDTH * TILE_WIDTH？

你有这个偏移量是因为在第一个记忆阶段你已经填满了“第一个”TILE_WIDTHxTILE_WIDTH共享内存的位置。

EDIT

下图说明了压扁螺纹索引之间的对应关系dest和共享内存位置。在图中，蓝色框代表通用图块的元素，而红色框代表相邻图块的元素。蓝色和红色框的并集对应于整体共享内存位置。如您所见，所有256线程块的线程参与填充绿线上方共享内存的上部部分，而只有145参与填充绿线以下共享内存的下部。现在你也应该明白了TILE_WIDTH x TILE_WIDTH offset.

请注意，您最多有2由于参数的特定选择，每个线程的内存负载。例如，如果您有TILE_WIDTH = 8，那么线程块中的线程数为64，而共享内存大小为12x12=144，这意味着每个线程负责执行at least 2共享内存写入144/64=2.25.