对于未标记的树，“展开”的正确定义是什么？

我一直在思考如何实现相当于unfold对于以下类型：

data Tree a = Node (Tree a) (Tree a) | Leaf a | Nil

自标准制定以来，这一点并不是立即显而易见的unfoldfor 列表返回一个值和下一个种子。对于这种数据类型，它没有意义，因为在到达叶节点之前没有“值”。这样，只有返回新种子或停止某个值才真正有意义。我正在使用这个定义：

data Drive s a = Stop | Unit a | Branch s s deriving Show

unfold :: (t -> Drive t a) -> t -> Tree a
unfold fn x = case fn x of
    Branch a b -> Node (unfold fn a) (unfold fn b)
    Unit a     -> Leaf a
    Stop       -> Nil

main = print $ unfold go 5 where
    go 0 = Stop
    go 1 = Unit 1
    go n = Branch (n - 1) (n - 2)

虽然这似乎有效，但我不确定这是否应该是这样。那么，这就是问题：正确的方法是什么？

如果您将数据类型视为函子的固定点，那么您可以看到您的定义是列表情况的合理概括。

module Unfold where

这里我们从定义函子的不动点开始f: 这是一层f接下来是一些更多的修复点：

newtype Fix f = InFix { outFix :: f (Fix f) }

为了让事情更清楚一些，这里是与列表和树相对应的函子的定义。它们的形状与数据类型基本相同，只是我们用额外的参数替换了递归调用。换句话说，他们描述了什么一层列表/树看起来像并且在可能的子结构上是通用的r.

data ListF a r = LNil | LCons a r
data TreeF a r = TNil | TLeaf a | TBranch r r

列表和树分别是 ListF 和 TreeF 的固定点：

type List a = Fix (ListF a)
type Tree a = Fix (TreeF a)

无论如何，希望您现在对这个固定点业务有更好的直觉，我们可以看到有一种定义固定点的通用方法unfold对于这些功能。

给定一个原始种子以及一个获取种子和构建的函数一层 of f当递归结构是新的种子时，我们可以构建一个完整的结构：

unfoldFix :: Functor f => (s -> f s) -> s -> Fix f
unfoldFix node = go
  where go = InFix . fmap go . node

这个定义专门针对通常的unfold在列表或您对树的定义中。换句话说：你的定义确实是正确的。