Flash AS3 中的文本链接

因此，我自己为一些通过 Dropbox 工作的朋友制作了一个“wiki”式的应用程序，这意味着所有文件都存储在本地并由每个人更新。

每个文件都是由 Flash 拉入的 .txt 文件，然后使用简单的导航和搜索工具显示。

现在我正尝试更进一步并链接其内容中的文章。例子：

第 1 条称为“苹果”。其内容是：“苹果很好吃。” 第 2 条称为“熊”。其内容是：“熊经常吃苹果。”

现在，当用户打开第 2 条时，我希望他们能够单击“苹果”一词，然后打开第 1 条（“苹果”）。

我想知道如何创建在动态文本框中单击特定单词时触发的事件。不是整个动态文本框。

我曾想过创建可点击的单词形状的影片剪辑并将它们分层在单词上，但如果有更简单的选项可用，那就太麻烦了。

您可以使用文本框htmlText http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/TextField.html#htmlText属性来动态地建立单词链接。然后使用TextEvent.LINK http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/text/TextField.html#event:link捕获单击的单词的事件。

在用内容填充文本框之前，只需迭代“关键字”列表并执行.replace("keyword", '<a href="event:keyword">keyword</a>');

因此，您的代码将类似于：

// get the file contents using whatever method you use
var contents:String = getFileContents("page2.txt");

// assuming you have your keywords in an array
var keywords:Array = ["Apples", "Pears"];
for each (var keyword:String in keywords) {
    // replace the current keyword with a version of itself wrapped in a link
    contents = contents.replace(keyword, '<a href="event:' + keyword + '">' + keyword + '</a>');
}

yourTextField.htmlText = contents;

// add an eventlistener for the click
yourTextField.addEventListener(TextEvent.LINK, linkClicked);
function linkClicked(e:TextEvent):void {
    // load the article for the clicked word =]
    loadPage(e.text);
}

UPDATE
如果您想忽略关键字的大小写，因此“apples”将匹配“Apples”（“aPpLeS”也将如此），您需要使用正则表达式，以便您也可以按原样保留单词文本：

// build a |-separated list of keywords
var keywordList:String = "";
for each (var keyword:String in keywords) {
    keywordList += ((keywordList != "") ? "|" : "") + keyword;
}
// build the regex and replace each keyword in-place
var pattern:RegExp = new RegExp("(" + keywordList + ")", "gi"); // "i" for ignore-case =]
contents = contents.replace(pattern, '<a href="event:$1">$1</a>');

上面构建的原因|- 分隔的关键字列表并执行单个替换（而不是每个关键字的替换）是因为分隔列表将按顺序执行替换，并且不允许找到的关键字破坏前一个关键字插入的 HTML（例如，例如，您有一个关键字“event” - 如果将其替换为<a href="<a href="event:event">event</a>:keyword1">keyword1</a>).

文本的原始大小写将随事件一起发送。您可以搜索所有现有关键字并将它们与传递给事件的关键字进行比较（将两者都转换为小写）.toLowerCase()用于比较），或者您可以制定一个规则，主关键字是always小写，不必担心每次都搜索列表。