Perl Moose：仅在 BUILD 子例程中提到时才设置属性

我正在构建一个脚本，该脚本以递归方式构建目录的子目录/文件的名称以及这些子目录中的文件的名称作为对象：

package Dir;
use Moose;
use Modern::Perl;
use File;
use strict;
use warnings;

has 'path' => (is => 'ro', isa => 'Str', required => 1); 
has 'name' => (is => 'ro', isa => 'Str', lazy => 1, default => sub { my $self = shift; my ($name) = $self->path =~ /\/([^\/]*)$/; return $name; } );
has 'subdirs' => (is => 'rw', isa => 'ArrayRef[Dir]' );  
has 'files' => (is => 'rw', isa => 'ArrayRef[File]' );  
has 'num_dirs' => (is => 'ro', isa => 'Int', lazy => 1, default => sub { my $self = shift; scalar @{$self->subdirs}; } );


sub BUILD {
  my $self = shift;
  my $path = $self->path;

  # run some tests
  logf('Path to the directory does not exist.')             if (!-e $path);
  logf('The path should point to a directory, not a file.') if (!-d $path);

  # populate subdirs attribute with Dir objects
  opendir my $dh, $path or die "Can't opendir '$path': $!";

  # Get files and dirs and separate them out into categories
  my @dirs_and_files = grep { ! m{^\.$|^\.\.$} } readdir $dh;
  closedir $dh or die "Can't closedir '$path': $!";
  my @subdir_names        = grep { -d "$path/$_" } grep { !m{^\.}  } @dirs_and_files;
  my @file_names          = grep { -f "$path/$_" } grep { !m{^\.}  } @dirs_and_files;

  # Create objects
  my @dir_objects =          map { Dir->new  ( path => $path . '/' . $_ ) } @subdir_names;
  my @file_objects =         map { File->new ( path => $path . '/' . $_ ) } @file_names;

  # Populate this with file and directory objects
  $self->subdirs             ( \@dir_objects );
  $self->files               ( \@file_objects );
}

1;

请注意，代码有一个files属性包含一个数组File对象。 AFile具有以下属性：

has 'path' => (is => 'ro', isa => 'Str', required => 1); 
has 'name' => (is => 'ro', isa => 'Str', lazy => 1, default => sub { my $self = shift; my ($name) = $self->path =~ /\/([^\/]*)$/; return $name; } );

问题是name当 a 时，属性永远不会被设置File对象被创建。我不知道为什么。

编辑1：解决方案（某种程度上）所以，我把这个放进去File对象以查看它是否触发了属性的创建：

sub BUILD {
  my $self = shift;
}

这并没有解决问题。然而，这确实：

sub BUILD {
  my $self = shift;
  $self->name;
}

但我的问题是，为什么我需要这样做？

问题是如果有尾部斜杠，您的模式就会失败。

my ($name) = $self->path =~ /\/([^\/]*)$/;

If $self->path is /some/thing有用。如果它是/some/thing/它“有效”但是[^\/]*愉快地匹配一个空字符串。所以你不会收到任何警告。

您可以输入可选的斜杠，并将其更改为匹配一个或多个非斜杠。另外，通过使用替代分隔符，我们可以清理所有倾斜的牙签。

my ($name) = $self->path =~ m{/ ([^/]+) /? $}x;

但实际上不应该用正则表达式来解析路径。使用许多内置模块之一，例如文件::基本名称 https://metacpan.org/pod/File::Basename or 文件::规格 https://metacpan.org/pod/File::Spec

return basename($self->path);

一些旁注。

Moose 启动速度非常慢，最适合长时间运行的进程，例如 Web 服务器。对于像 File 和 Dir 类这样通用的东西，请考虑使用Moo https://metacpan.org/pod/Moo。它与 Moose 大部分兼容，速度更快，并且与类型::标准 https://metacpan.org/pod/Types::Standard，打字效果更好。例如，最好创建一个 StrNotEmpty 类型来避免此类问题。

除非这是一个练习，否则 Perl 已经有一个很棒的模块来完成此类事情。调查路径::小 https://metacpan.org/pod/Path::Tiny.