Erlang：使用 gen_tcp:controlling_process 避免竞争条件

我正在按照以下顺序实现简单的 tcp 服务器：

{ok, LS} = gen_tcp:listen(Port,[{active, true}, {reuseaddr, true}, {mode, list}]),
{ok, Socket} =  gen_tcp:accept(LS),
Pid = spawn_link(M, F, [Socket]),           
gen_tcp:controlling_process(Socket, Pid) 

使用选项 {active, true} 可能会导致竞争条件，即在调用“controlling_process”之前新数据包到达套接字进程，这将导致 {tcp,Socket,Data} 消息到达父进程而不是父进程孩子。

如何避免这种情况？

你是对的。在这种情况下你肯定需要{active, false}在侦听套接字选项之间传递。考虑一下这段代码：

-define(TCP_OPTIONS, [binary, {active, false}, ...]).

...

start(Port) ->
    {ok, Socket} = gen_tcp:listen(Port, ?TCP_OPTIONS),
    accept(Socket).

accept(ListenSocket) ->
    case gen_tcp:accept(ListenSocket) of
        {ok, Socket} ->
            Pid = spawn(fun() ->
                io:format("Connection accepted ~n", []),
                enter_loop(Socket)
            end),
            gen_tcp:controlling_process(Socket, Pid),
            Pid ! ack,
            accept(ListenSocket);
        Error ->
            exit(Error)
    end.

enter_loop(Sock) ->
    %% make sure to acknowledge owner rights transmission finished
    receive ack -> ok end,
    loop(Sock).

loop(Sock) ->
    %% set soscket options to receive messages directly into itself
    inet:setopts(Sock, [{active, once}]),
    receive
        {tcp, Socket, Data} ->
            io:format("Got packet: ~p~n", [Data]),
            ...,
            loop(Socket);
        {tcp_closed, Socket} ->
            io:format("Socket ~p closed~n", [Socket]);
        {tcp_error, Socket, Reason} ->
            io:format("Error on socket ~p reason: ~p~n", [Socket, Reason])
    end.

因此，您不会失去任何东西，直到controlling_process成功了。众所周知，这个问题在互联网上已经被广泛讨论。 如果您想使用现成的解决方案，您肯定需要看看Ranch https://github.com/extend/ranch项目。