nasm 汇编linux定时器或睡眠

我正在尝试找到一种方法让我的代码在继续之前等待两秒钟。我在保护模式下使用Linux的nasm，所以我只能使用int 80h。我找到了一个syscall称为“alarm” (27) 另一个叫“pause“ (29)。但是，当我尝试使用这些时，程序会等待并完成，而不是继续执行。我还发现了另一个syscall，sigaction，它改变了信号的行为（所以我认为它可以用来让程序忽略alarm生成的信号而不是退出），但我不太明白sigaction是如何工作的。谢谢你的帮助。 有用的链接：http://man7.org/linux/man-pages/man2/alarm.2.html http://man7.org/linux/man-pages/man2/alarm.2.html http://man7.org/linux/man-pages/man2/sigaction.2.html http://man7.org/linux/man-pages/man2/sigaction.2.html

有一个系统调用可以让程序休眠，sys_nanosleep http://linux.die.net/man/2/nanosleep:

 sys_nanosleep : eax = 162, ebx = struct timespec *, ecx = struct timespec *

this struct timespec结构有两个成员：

 ;; This is for 32-bit.  Note that x86-64 uses 2x 64-bit members
tv_sec   ; 32 bit seconds
tv_nsec  ; 32 bit nanoseconds

该结构可以在 nasm 中声明为：

section .data

  timeval:
    tv_sec  dd 0
    tv_usec dd 0

然后设置值并将其称为：

mov dword [tv_sec], 5
mov dword [tv_usec], 0
mov eax, 162
mov ebx, timeval
mov ecx, 0
int 0x80

然后程序将休眠 5 秒钟。一个完整的例子：

global  _start

section .text
_start:

  ; print "Sleep"
  mov eax, 4
  mov ebx, 1
  mov ecx, bmessage
  mov edx, bmessagel
  int 0x80

  ; Sleep for 5 seconds and 0 nanoseconds
  mov dword [tv_sec], 5
  mov dword [tv_usec], 0
  mov eax, 162
  mov ebx, timeval
  mov ecx, 0
  int 0x80

  ; print "Continue"
  mov eax, 4
  mov ebx, 1
  mov ecx, emessage
  mov edx, emessagel
  int 0x80

  ; exit
  mov eax, 1
  mov ebx, 0
  int 0x80

section .data

  timeval:
    tv_sec  dd 0
    tv_usec dd 0

  bmessage  db "Sleep", 10, 0
  bmessagel equ $ - bmessage

  emessage  db "Continue", 10, 0
  emessagel equ $ - emessage