gfortran 中的清零

有没有办法强制 gfortran 中的下溢清零？

我不敢相信这是第一次有人问这个问题，但我在任何地方都找不到任何相关内容。如果这是重复的，我会承担责任。

您可以使用支持 Fortran 2003 IEEE 模块的最新版本的 gfortran 来实现此目的。该标准定义了两种下溢模式——渐进式和突然式。突发是您想要的一种，它将下溢设置为 0 并发出下溢浮点异常信号。您可以使用以下函数测试对控制下溢模式的支持ieee_support_underflow_control(X)它测试真实 X 类型的下溢控制，如果支持，则返回逻辑 true。如果支持的话，您可以call ieee_set_underflow_mode(.false.)设置突然下溢模式。

下面是一个测试程序，您可以使用它来测试默认真实类型的下溢控制支持：

program test
  use, intrinsic :: ieee_arithmetic
  use, intrinsic :: iso_fortran_env, only: compiler_version, compiler_options
  implicit none
  logical :: underflow_support, gradual, underflow
  real :: fptest
  integer :: i

  print '(4a)',  'This file was compiled by ', &
       compiler_version(), ' using the options ', &
       compiler_options()
  fptest = 0.0
  underflow_support = ieee_support_underflow_control(fptest)
  if (underflow_support) then
     print *,'Underflow control supported for the default real kind'
  else
     stop 'no underflow control support'
  end if

  call ieee_set_underflow_mode(.false.)
  call ieee_get_underflow_mode(gradual)
  if (.not.gradual) then 
     print *,'Able to set abrupt underflow mode'
  else
     stop 'error setting underflow mode'
  end if

  fptest = 2e-36
  do i=1,50 ! 50 iterations max
     fptest = fptest * 0.5
     print '(e15.10)',fptest
     call ieee_get_flag(ieee_underflow,underflow)
     if (underflow) print *,'Underflow exception signaling'
     if (fptest == 0.0) exit
  end do

end program test

使用 gfortran 版本 5.2.0，该程序输出：

This file was compiled by GCC version 5.2.0 using the options -mtune=generic -march=x86-64 -fno-unsafe-math-optimizations -frounding-math -fsignaling-nans
 Underflow control supported for the default real kind
 Able to set abrubpt underflow mode
.1000000036E-35
.5000000180E-36
.2500000090E-36
.1250000045E-36
.6250000225E-37
.3125000112E-37
.1562500056E-37
.0000000000E+00
 Underflow exception signaling

编译器选项标志-fno-unsafe-math-optimizations -frounding-math -fsignaling-nansgfortran 5.2 文档建议在使用 IEEE 模块时使用，以确保遵守标准。