将派生类型中的指针分配给 Fortran 中相同类型中的目标

我想在包含在同一派生类型中的派生类型中分配一个指针。下面的代码给了我下面的错误。这是怎么回事，我该如何解决这个问题？

   24 |         zoos(i)%tigers(1) => zoos(i)%animals(1, 1)
      |        1
Error: Expected bounds specification for 'zoos' at (1)

module mo_zoo
    implicit none
    type zoo
        integer, dimension(:,:), pointer :: animals
        integer, dimension(:), pointer :: tigers
        integer, dimension(:), pointer :: ducks
    end type zoo
   
    save
        type(zoo), dimension(:), pointer :: zoos
end module mo_zoo

program test
    use mo_zoo
    implicit none
    integer :: n_zoos
    integer :: i

    n_zoos = 4
    allocate(zoos(n_zoos))

    do i = 1, n_zoos
        allocate(zoos(i)%animals(10, 2))
        zoos(i)%tigers(1) => zoos(i)%animals(1, 1)
        zoos(i)%ducks(1) => zoos(i)%animals(1, 2)
    end do
end program test

该问题与派生类型无关，并且错误消息是错误的。

问题是zoos(i)%ducks是一个指向数组的指针，而不是指针数组，所以你需要指向zoos(i)%ducks at zoos(i)%animals(:, 2)， 而不是zoos(i)%ducks(1) at zoos(i)%animals(1, 2).

我之前谈过这个在这个答案中 https://stackoverflow.com/questions/67033612/array-of-pointers-in-fortran/67056904#67056904.

我相信这符合您的要求：

module mo_zoo
    implicit none
    type zoo
        integer, dimension(:,:), pointer :: animals
        integer, dimension(:), pointer :: tigers
        integer, dimension(:), pointer :: ducks
    end type zoo
   
    save
        type(zoo), dimension(:), pointer :: zoos
end module mo_zoo

program test
    use mo_zoo
    implicit none
    integer :: n_zoos
    integer :: i

    n_zoos = 4
    allocate(zoos(n_zoos))

    do i = 1, n_zoos
        allocate(zoos(i)%animals(10, 2))
        zoos(i)%tigers => zoos(i)%animals(:, 1)
        zoos(i)%ducks => zoos(i)%animals(:, 2)
    end do
end program test

我还想提出一个框架挑战。正如评论中（尤其是 Ian Bush）所指出的，Fortran 中的指针非常容易出错。

我建议更换任何分配的pointers with allocatables。这些allocatable还需要target如果他们有pointers 指着他们，就像这样：

module mo_zoo
    implicit none
    type zoo
        integer, dimension(:,:), allocatable :: animals
        integer, dimension(:), pointer :: tigers
        integer, dimension(:), pointer :: ducks
    end type zoo
   
    save
        type(zoo), dimension(:), allocatable, target :: zoos
end module mo_zoo

program test
    use mo_zoo
    implicit none
    integer :: n_zoos
    integer :: i

    n_zoos = 4
    allocate(zoos(n_zoos))

    do i = 1, n_zoos
        allocate(zoos(i)%animals(10, 2))
        zoos(i)%tigers => zoos(i)%animals(:, 1)
        zoos(i)%ducks => zoos(i)%animals(:, 2)
    end do
end program test

使用有很多优点allocatables over pointer尽可能：

• The memory held by allocatables will automatically be freed when the allocatables drop out of scope¹.
• 编译器可以做出更强有力的假设allocatable比大约pointers，有时会导致更快的代码。

¹ At least, this is true according to the Fortran standard. There are several outstanding problems with some compilers (notably this bug https://gcc.gnu.org/bugzilla/show_bug.cgi?id=90068) relating to finalisation.