在 groovy shell 中使用 groovy 类别

我正在使用 Groovy 类别在一些 DSL 下工作，我想找到一种方法来使用我的 DSL 和 groovy shell，而无需显式编写use(MyCategory){ myObject.doSomething() }对于每个命令。

例如，假设我有以下玩具类别：

class MyCategory {
    static Integer plus(Integer integer, String string){
        return integer + Integer.valueOf(string)
    }
}

然后，我可以使用这个类别groovysh通过以下方式：

groovy> use(MyCategory){ 2 + '3' } //gives 5

那么有什么办法可以设置MyCategory全球所有人groovysh命令，因此不必每次都将我的命令包装在use(MyCategory) { ... }？例如：

groovy> useGlobally(MyCategory); //call something like this only once
groovy> 2 + '3' //automatically uses MyCategory and gives 5

类别的想法是关闭元编程的范围。为什么不使用metaClass在这种情况下？

groovy:000> class MyCategory {
groovy:001>     static Integer plus(Integer integer, String string){
groovy:002>         return integer + Integer.valueOf(string)
groovy:003>     }
groovy:004> }
===> true
groovy:000> Integer.metaClass.mixin MyCategory
===> null
groovy:MyCategory@131fa4b> 2 + '4'
===> 6
groovy:MyCategory@131fa4b> 

Update：对于很多方法，您可以迭代静态方法的第一个参数并将它们混合到各自的参数类型类中。

class MyCategory {
    static global() {
        MyCategory.metaClass.methods
            .findAll { it.isStatic() && !it.name.startsWith("__") && it.name != "global" }
            .each { it.nativeParameterTypes[0].mixin MyCategory }
    }

    static Integer plus(Integer integer, String string){
        return integer + Integer.valueOf(string)
    }

    static String yell(String a, times) {
      a.toUpperCase() * times + "!!!"
    }
}


MyCategory.global()


assert "a".yell(3) == "AAA!!!"
assert 2+'3' == 5