在 Perl 6 中查找上周五的日期？

我想生成一个从周一到周四的上周五结束的序列，如果该序列从周六和周日开始，则生成上周五结束的序列。也就是说，假设今天是2018-05-09，那么上周五是2018-05-04, 如果今天是2018-05-12，那么上周五是also 2018-05-04。所以我写：

(Date.today, *.earlier(:1day) ... ( *.day-of-week==5 && *.week[1]+1==Date.today.week[1] )).tail # Output: 2018-05-06

但结果是2018-05-06代替2018-05-04.

然后我用了一个Junction https://docs.perl6.org/type/Junction:

(Date.today, *.earlier(:1day) ... all( *.day-of-week==5,  *.week[1]+1==Date.today.week[1] )).tail # Output: 2018-05-04

Why &&第一种情况是错误的吗？这... https://docs.perl6.org/language/operators#index-entry-..._operators运营商说：

右侧将有一个端点，可以是 Inf 或 * 表示“无限”列表（其元素仅根据需要生成）、一个在 True 时结束序列的表达式，或其他元素（例如 Junctions）。

有什么问题吗&&操作员？

问题是你的结束条件

*.day-of-week==5 && *.week[1]+1==Date.today.week[1]

这是两个WhateverCode lambda，每个都有 1 个参数。

*.day-of-week==5

*.week[1]+1==Date.today.week[1]

由于代码对象是真值，因此&&运算符移至第二个。因此，当到达前一周的星期日时，序列就会停止。

即使代码是单个 lambda，它也不会像您期望的那样工作，因为它将是一个带有两个参数的 lambda。

进行此检查的正确方法是使用某种块。

{.day-of-week==5 && .week-number+1 == Date.today.week-number}

将其包装在子例程中可能是一个好主意，以便您可以测试它。

sub last-friday ( Date:D $date ) {
  # cache it so that it doesn't have to be looked up on each iteration
  my $week-number = $date.week-number - 1;

  (
    $date,
    *.earlier( :1day )

    ...

    {
          .day-of-week == 5
      &&
          .week-number == $week-number
    }
  ).tail
}

say last-friday Date.new: :year(2018), :month( 5), :day( 9); # 2018-05-04
say last-friday Date.new: :year(2018), :month( 5), :day(12); # 2018-05-04

say Date.today.&last-friday; # 2018-05-04

您也可以计算正确的日期。

sub last-friday ( Date:D $date ) {
  $date.earlier:
    days => (
      $date.day-of-week # reset to previous sunday
      + 2               # go two days earlier to get friday
    )
}

say last-friday Date.new: :year(2018), :month( 5), :day( 9); # 2018-05-04
say last-friday Date.new: :year(2018), :month( 5), :day(12); # 2018-05-04

say Date.today.&last-friday; # 2018-05-04