URLLoader 数据到 BitmapData

我正在尝试加载 .SWF 文件旁边的图像文件。像这样的东西：

var loader:URLLoader = new URLLoader();
loader.dataFormat = URLLoaderDataFormat.BINARY;
loader.addEventListener(Event.COMPLETE, function(e:Event):void {
    trace(typeof(loader.data));
    graphic = spritemap = new Spritemap(loader.data, 32, 32);
    ...
}

但这是我得到的输出：

object
[Fault] exception, information=Error: Invalid source image.

问题是 loader.data 具有图像的字节，但不是 BitmapData 实例，这正是 Spritemap 所期望的。

如何转换为BitmapData？

Thanks

// define image url
var url:URLRequest = new URLRequest("http://sstatic.net/ads/img/careers2-ad-header-so.png");

// create Loader and load url
var img:Loader = new Loader();
img.load(url);

// listener for image load complete
img.contentLoaderInfo.addEventListener(Event.COMPLETE, loaded);

// attaches the image when load is complete
function loaded(e:Event):void
{
    var bitmap:Bitmap = e.target.content;
    doStuffWithBitmapData(bitmap.bitmapData);

    addChild(bitmap);

    // remove listener
    e.target.removeEventListener(Event.COMPLETE, loaded);
}

/**
 * Handle loaded BitmapData
 * @param bmd The loaded BitmapData
 */
function doStuffWithBitmapData(bmd:BitmapData):void
{
    trace(bmd);

    // your code
}

基本上;

你应该使用Loader, not URLLoader。您可以访问BitmapData装载的Bitmap with bitmap.bitmapData.