只能使用releaseImplementation和debugImplementation从maven添加Kotlin Multiplatform Mobile库

每次我将 Kotlin Multiplatform Mobile 库发布到 Maven Central 时，我似乎唯一可以在 Android 应用程序中添加/使用 Android 依赖项的方法是添加releaseImplementation and debugImplementation

Example

releaseImplementation 'io.github.tyczj.lumberjack:Lumberjack-android:1.0.0@aar'
debugImplementation 'io.github.tyczj.lumberjack:Lumberjack-android-debug:1.0.0@aar'

而不是“正常”的方式，你只有一个implementation

implementation 'io.github.tyczj.lumberjack:Lumberjack-android:1.0.0'

这是我的 build.gradle 文件

plugins {
    kotlin("multiplatform") version "1.4.32"
    id("com.android.library")
    id("io.github.gradle-nexus.publish-plugin") version "1.1.0"
    id("maven-publish")
    id("signing")
}

group = "io.github.tyczj.lumberjack"
version = "1.0.2"

ext["signing.keyId"] = ""
ext["signing.password"] = ""
ext["signing.secretKeyRingFile"] = ""

repositories {
    google()
    mavenCentral()
    maven {
        setUrl("https://plugins.gradle.org/m2/")
    }
}

val javadocJar by tasks.registering(Jar::class) {
    archiveClassifier.set("javadoc")
}

val emptyJar by tasks.registering(Jar::class) {
    archiveAppendix.set("empty")
}

kotlin {
    android{
        publishLibraryVariants("release", "debug")
    }
    iosX64("ios") {
        binaries {
            framework {
                baseName = "lumberjack"
            }
        }
    }
    sourceSets {
        val commonMain by getting
        val commonTest by getting
        val androidMain by getting
        val androidTest by getting
        val iosMain by getting
        val iosTest by getting
    }
}

android {
    compileSdkVersion(29)
    sourceSets["main"].manifest.srcFile("src/androidMain/AndroidManifest.xml")
    defaultConfig {
        minSdkVersion(24)
        targetSdkVersion(29)
    }
    buildTypes {
        getByName("release") {
            isMinifyEnabled = false
        }
    }
}

afterEvaluate {
    publishing {
        repositories {
            maven {
                name = "sonatype"
                url = uri("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/")
                credentials {
                    username = rootProject.ext["ossrhUsername"]?.toString()
                    password = rootProject.ext["ossrhPassword"]?.toString()
                }
            }
        }

        publications.withType<MavenPublication> {

            artifact(javadocJar.get())

            pom{
                name.set("Lumberjack")
                description.set("Logging library for Kotlin Multiplatform Mobile applications")
                url.set("https://github.com/tyczj/Lumberjack")
                licenses {
                    license {
                        name.set("MIT")
                        url.set("https://opensource.org/licenses/MIT")
                    }
                }
                developers {
                    developer {
                        id.set("tyczj")
                        name.set("Jeff Tycz")
                        email.set("[email protected] /cdn-cgi/l/email-protection")
                    }
                }
                scm {
                    url.set("https://github.com/tyczj/Lumberjack")
                }
            }
        }
    }
}

ext["signing.keyId"] = rootProject.ext["signing.keyId"]?.toString()
ext["signing.password"] = rootProject.ext["signing.password"]?.toString()
ext["signing.secretKeyRingFile"] = rootProject.ext["signing.secretKeyRingFile"]?.toString()

signing {
    sign(publishing.publications)
}

apply(from = "${rootDir}/scripts/publish-root.gradle")

可以找到该库的完整源代码here https://github.com/tyczj/Lumberjack

我构建/发布 KMM 库（必须指定发布和调试实现）的方式有什么问题？

你不应该指定-android后缀，只需使用implementation("io.github.tyczj.lumberjack:Lumberjack:1.0.0").

这是有效的，因为依赖性变体解析基于Gradle 模块元数据 https://docs.gradle.org/current/userguide/publishing_gradle_module_metadata.html。此元数据只是与您的库一起发布的另一个文件（它具有.module扩展名），它包含所有变体的描述。当您将库作为一个整体发布时，顶级工件io.github.tyczj.lumberjack:Lumberjack包含整个库的元数据，允许 gradle 选择正确的变体。

另一种选择是确保您的-android工件包含适当的模块元数据以及发布和调试变体。我相信发布库变体按口味分组 https://kotlinlang.org/docs/mpp-publish-lib.html#publish-an-android-library是告诉发布者插件这样做的方法，但我还没有尝试过。