当给定闪光角度和速度时，计算物体的轨迹

我正在尝试从大炮中发射炮弹并使其遵循现实的路径。射击角度根据大炮的方向而变化（自动定向到鼠标指针）。所以我想弄清楚的是，当给定角度和设定速度时，如何沿着抛物线路径移动炮弹。

我读到，这可以在没有复杂的三角学的情况下完成（在高中时从未听过），并且可以通过在每个刻度上将重力添加到 yVelocity 来简单地计算。然而，此时，我不知道如何计算初始 yVelocity（同样，取决于大炮方向）。

您可以在此处查看当前动画：http://kate.ict.op.ac.nz/~welfajw1/portfolio/videos/task3-assignment2.swf http://kate.ict.op.ac.nz/~welfajw1/portfolio/videos/task3-assignment2.swf

这一切都是在AS3中完成的，我的代码如下：

主要时间线代码：

import flash.display.*;
import flash.events.*;
import flash.geom.*;

var cannonball:ball_mc;
var angleDegree;

myCannon.addEventListener(Event.ENTER_FRAME, cannonEnterFrame);

function cannonEnterFrame(pEvt)
{
    var mc = myCannon;
    var mg = myCannon.myGun;

    //find angle for orientation
    var angleRadian = Math.atan2(mouseY - mc.y, mouseX - mc.x);

    //convert to degrees
    angleDegree = angleRadian * 180 / Math.PI;

    //limit rotation
    if(angleDegree > -63 && angleDegree < 20)
        mg.rotation = angleDegree;
}

stage.addEventListener(Event.ENTER_FRAME, stageRefresh);

function stageRefresh(pEvt)
{
    if (cannonball)
    {
        //move every "tick"
        cannonball.move();
    }
}

stage.addEventListener(MouseEvent.CLICK, mouseClicked);

function mouseClicked(pEvt)
{
    //starting position of the ball
    cannonball = new ball_mc(100, 475);

    //SEND IN INITIAL x, y VELOCITIES
    cannonball.fire(20, angleDegree);

    //add to stage
    stage.addChild(cannonball);
}

ball_mc代码：

package 
{

    import flash.display.MovieClip;
    import flash.sensors.Accelerometer;
    import flashx.textLayout.formats.Float;


    public class ball_mc extends MovieClip
    {
        //constant gravity
        public static const g:Number = 2;

        //starting velocities
        private var ux:Number;
        private var uy:Number;

        public function ball_mc(startX:int, startY:int)
        {
            x = startX;
            y = startY;
        }

        public function fire(vx:Number, vy:Number):void
        {
            ux = vx;
            uy = vy;
        }

        public function move():void
        {
            //distance moved in x dir
            var sx:Number = ux; 
            //new velocity in y dir
            var vy:Number = uy + g;
            //distance moved in y dir
            var sy:Number = uy + g/2;

            //apply movement
            x += sx;
            y += sy;

            //save new y velocity
            uy = vy;
        }
    }
}

你需要一点物理知识。

初始速度必须使用您自己添加的一些标准来计算。一个例子是通过按下鼠标时鼠标与大炮之间的距离来计算初始速度。如果距离较大，则弹丸的速度较大；如果距离较小，则弹丸的速度较小。

您添加一个类型为 ENTER_FRAME 的事件侦听器。

我猜这是二维动画，所以你必须在任何时间点找到当前的 x 和 y。

这是一些代码：

var TimeperFrame:Number = 1/fps //fps is not a constant, here you should add a number, a value that you previously added in fla. document properties. I usualy use 60 fps
var Time:Number = 0;

addEventListener(ENTER_FRAME, movingCannonBall);
function movingCannonBall(e:Event):void
{
   Time += TimeperFrame;
}

现在这是射弹轨迹的方程。

x = xo + vxo·t

y = yo + vyo·t - 0.5·g·t^2

yo = 你的炮弹的初始高度

vyo = 初始 y 速度； vyo = vo·sin θ

t = 过去的时间，我们通过上层代码控制

g = 地球表面加速度 (9.81 m/s^2)

xo = 起点的初始距离

vxo = 初始 x 速度； vxo = vo·cos θ

现在，在上面的代码中，我们添加这些方程，它应该如下所示：

var TimeperFrame:Number = 1/fps
var Time:Number = 0;
var initx: Number = cannonball.x;
var inity: Number = cannonball.y;
var initVelocity: Number = (you define initial Velocity by your criteria)
var G: Number = 9.81;

addEventListener(ENTER_FRAME, movingCannonBall);
function movingCannonBall(e:Event):void
{
   Time += TimeperFrame;
   cannonball.x = initx + Math.cos(angle) * initVelocity * Time;
   cannonball.y = inity + Math.sin(angle) * initVelocity * Time - G * Time * Time * 0.5
}

这应该有效。我已经多次使用这个代码，它很高效，而且很简单。