如何从 VB-6 旧应用程序中启动屏幕键盘程序

我正在尝试从 Windows 10-32 或 Windows 10-64 位计算机上的 VB-6 应用程序中“shell osk.exe”。

过去我们只是简单地使用：

Private Sub Command1_Click()
Dim strTemp As String
Dim fso1 As New FileSystemObject
strTemp = fso1.GetSpecialFolder(SystemFolder) & "\osk.exe"

Dim lngReturn As Long
Let lngReturn = ShellExecute(Me.hwnd, "Open", strTemp, vbNullString, "C:\", SW_SHOWNORMAL)

lblReturn.Caption = CStr(lngReturn)

end sub

我们还使用了更简单的“shell”命令；两者都不起作用。

在过去，这效果很好。我们还可以从我们的程序中打开 NotePad、msPaint 和其他一些实用程序。我们使用工业触摸屏电脑，为了方便起见，我们在“设置”页面上放置了一些按钮来快速访问这些类型的帮助程序。我不想等待程序，我们的代码有它自己的“触摸屏键盘”。用户仅当想要在我们的主应用程序之外执行某些工作时才会使用 Windows OSK。

对于 Windows XP，所有这些程序都可以正常打开。现在，对于 Windows 10，只有 OSK.exe 程序无法启动。查看返回代码，返回的错误是“2” - 文件未找到（我假设）。但是在 c:\windows\system32 文件夹中查看文件 'osk.exe' 以及 mspaint.exe 和 notepad.exe 。

是否有某些 Windows 设置从我的程序中隐藏了真正的 osk.exe？

感谢您的任何建议。

在我的 64 位 Windows 10 上，您的代码的行为如您所说。看起来在 64 位 Windows 上您必须禁用 WOW 64 重定向：

Option Explicit

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, _
    ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, _
    ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

Private Const SW_SHOWNORMAL = 1

Private Declare Function Wow64EnableWow64FsRedirection Lib "kernel32.dll" (ByVal Enable As Boolean) As Boolean '// ****Add this****

Private Sub Command1_Click()
    Dim fso1 As New FileSystemObject
    Dim strTemp As String

    strTemp = fso1.GetSpecialFolder(SystemFolder) & "\osk.exe"

    Dim lngReturn As Long
    Wow64EnableWow64FsRedirection False '// ****Add this****
    Let lngReturn = ShellExecute(Me.hwnd, "open", strTemp, vbNullString, "C:\", SW_SHOWNORMAL)
    Wow64EnableWow64FsRedirection True '// ****Add this****
    lblReturn.Caption = CStr(lngReturn)
End Sub

这段代码在 Windows 10 64 位上就像一个魅力。还在 Windows 10 32 位上进行了测试...也适用。