通用高阶函数

当我将泛型函数作为本地值传递时，但在作为参数传递时却不能使用具有不同类型参数的泛型函数时，是否有原因？ 例如：

let f = id

let g (x,y) = (f x, f y)

g ( 1, '2')

工作正常，但如果我尝试将函数作为参数传递

let g f (x,y) = (f x, f y)

g id ( 1, '2')

它失败了，因为它采用版本 f 并尝试应用它两次。

我找到了一个解决方法，但它迫使我编写我传递的函数的两倍：

let g f1 f2 (x,y) = (f1 x, f2 y)

g id id ( 1, '2')

这是我第二次遇到这个问题。

为什么它的行为如此，如果函数是本地值或者作为参数传递，那么它不应该是相同的？

有没有办法在不重复功能的情况下做到这一点？

黑客，也许使用显式类型约束、内联魔法、引号？

这是内联魔法。 让我们采用 kvb 的代码并定义一个gmap处理所有情况的函数：

let inline gmap f (x, y) = f $ x, f $ y

type One = One with static member ($) (One, x) = 1  // Example1 ConvertAll
type Id  = Id  with static member ($) (Id , x) = x  // Example2 PassThrough

type SeqSingleton  = SeqSingleton  with static member ($) (SeqSingleton , x) = seq [x]
type ListSingleton = ListSingleton with static member ($) (ListSingleton, x) = [x]
type ListHead      = ListHead      with static member ($) (ListHead, x) = List.head x

// Usage
let pair1 = gmap One ("test", true)
let pair2 = gmap Id  ("test", true)
let pair3 = gmap SeqSingleton  ("test", true)
let pair4 = gmap ListSingleton ("test", true)
let pair5 = gmap ListHead (["test";"test2"], [true;false])

let pair6 = ("test", true) |> gmap ListSingleton |> gmap ListHead

(* results
val pair1 : int * int = (1, 1)
val pair2 : string * bool = ("test", true)
val pair3 : seq<string> * seq<bool> = (["test"], [true])
val pair4 : string list * bool list = (["test"], [true])
val pair5 : string * bool = ("test", true)
val pair6 : string * bool = ("test", true)
*)

UPDATE

也可以使用更通用的gmap函数定义here https://gist.github.com/gusty/0cc6d0c379d3845f0e334a84e3b13a37那么它也适用于 n 组 (n