本节通过ESP8266NodeMCU连接到wifi，通过点灯blinker app来开关灯，同时也可以通过小爱同学语音控制开关灯。
准备工作：
1.手机端下载【点灯blinker】软件，应用市场可以下载，并注册账号；
注册完成后，添加设备
返回，点进去设备里，添加按键，并将按键名更改为btn-abc
2.在手机上下载米家APP，并注册账号，绑定blinker的账号；
打开米家APP，点击【我的】，点击【其他平台设备】
点击右上角的添加设备，往下翻，找到点灯科技。
绑定完成后，点击同步设备，就可以看到刚刚添加的设备。
3.在手机上下载小爱同学，小米手机自带小爱同学，无需下载，如果是其他品牌手机，需要下载，绑定米家账号；
打开小爱同学，登录米家账号，点击智能家居，就可以看到刚添加的设备，如小灯。
4.Arduino安装了ESP8266库文件；
如果没有安装库文件，参考以下步骤：
打开Arduino软件，在【文件-首选项-附加开发板管理器网址】填入：https://arduino.esp8266.com/stable/package_esp8266com_index.json
在【项目-加载库-管理库】，库管理器中搜索ESP8266，点击安装，默认安装最新版本。
5.安装Blinker库，同样在库管理器中搜索blinker，点击安装即可。
上面的步骤完成后，将以下代码上传到ESP8266NodeMCU开发板中。就可以用小爱同学语音控制开发板上的LED灯了。点灯blinker APP中，也可以通过按键来开关小灯。
代码：
#define BLINKER_WIFI
#define BLINKER_MIOT_LIGHT//支持小爱同学
#define BLINKER_WITHOUT_SSL //非SSL加密通信接入，省堆栈
#include <Blinker.h>
#define LED 2 // 板子上的灯
//下面3项需要根据实际填写
char auth[] = "xxx"; // blinker app提供的秘钥
char ssid[] = "xxx";// wifi 名字
char pswd[] = "xxx";// wifi 密码
bool wsState;
uint8_t wsMode = BLINKER_CMD_MIOT_DAY;
// 新建组件对象
BlinkerButton Button1("btn-abc");//注意：要和APP组件’数据键名’一致
// 按下BlinkerAPP按键即会执行该函数
void button1_callback(const String & state)
{
BLINKER_LOG("get button state: ", state);
digitalWrite(LED, !digitalRead(LED));
Blinker.vibrate();
}
//小爱电源类操作的回调函数:
//当小爱同学向设备发起控制, 设备端需要有对应控制处理函数
void miotPowerState(const String & state)
{
BLINKER_LOG("need set power state: ", state);
if (state == BLINKER_CMD_ON)
{
digitalWrite(LED, LOW); //低电平点灯
BlinkerMIOT.powerState("on");
BlinkerMIOT.print();
wsState=true;
}
else if (state == BLINKER_CMD_OFF)
{
digitalWrite(LED, HIGH); //高电平开灯
BlinkerMIOT.powerState("off");
BlinkerMIOT.print();
wsState=false;
}
}
//小爱同学 的回调查询函数，照抄即可。主要是查询 当前灯的状态
void miotQuery(int32_t queryCode)
{
BLINKER_LOG("MIOT Query codes: ", queryCode);
switch (queryCode)
{
case BLINKER_CMD_QUERY_ALL_NUMBER :
BLINKER_LOG("MIOT Query All");
BlinkerMIOT.powerState(wsState ? "on" : "off");
BlinkerMIOT.color(0);
BlinkerMIOT.mode(0);
BlinkerMIOT.colorTemp(1000);
BlinkerMIOT.brightness(1);
BlinkerMIOT.print();
break;
case BLINKER_CMD_QUERY_POWERSTATE_NUMBER :
BLINKER_LOG("MIOT Query Power State");
BlinkerMIOT.powerState(wsState ? "on" : "off");
BlinkerMIOT.print();
break;
default :
BlinkerMIOT.powerState(wsState ? "on" : "off");
BlinkerMIOT.color(0);
BlinkerMIOT.mode(0);
BlinkerMIOT.colorTemp(1000);
BlinkerMIOT.brightness(1);
BlinkerMIOT.print();
break;
}
}
void setup()
{
// 初始化串口，并开启调试信息，调试用可以删除
Serial.begin(115200);
BLINKER_DEBUG.stream(Serial);
// 初始化IO
pinMode(LED, OUTPUT);
digitalWrite(LED, HIGH); // 初始化 led 高电平 ，则灯熄灭状态
// 初始化blinker
Blinker.begin(auth, ssid, pswd);
Button1.attach(button1_callback);
//小爱同学务必在回调函数中反馈该控制状态
BlinkerMIOT.attachPowerState(miotPowerState);//注册回调函数
BlinkerMIOT.attachQuery(miotQuery);
}
void loop()
{
Blinker.run();
}以上是本次开发的全部记录，方便以后自己查阅，同时也希望能给他人一点借鉴。详细介绍，请参见点灯科技网址：https://www.diandeng.tech