CMakeLists.txt实例和语法介绍

2023-11-12

一、实例

1. 实例介绍

构建一个简单的加减法运算，需要调用静态库和动态库的实例。将add编译为静态库，sub编译为动态库。

目录架构：

-->$ tree -LF 2 ./
./
|-- add/
|   |-- add_build.sh*
|   |-- add.cpp
|   |-- add.h
|   |-- build/
|   `-- CMakeLists.txt
|-- CMakeLists.txt
|-- main_build.sh*
|-- main.cpp
`-- sub/
    |-- build/
    |-- CMakeLists.txt
    |-- sub_build.sh*
    |-- sub.cpp
    `-- sub.h

2. 目录 add，编译为静态库

// add.h
#pragma once
int test_add(int a, int b);

// add.cpp
#include "add.h"
int test_add(int a, int b)
{
    return a+b;
}

将加法运算编译为静态库

# CMakeLists.txt
cmake_minimum_required(VERSION 2.8)

# set the project name
project(add_static)

# 搜索当前目录下的所有.cpp文件
aux_source_directory(${CMAKE_CURRENT_LIST_DIR} src_list) 

# 生成静态库
set(libadd add)
add_library(${libadd} STATIC ${src_list})

执行脚本 add_build.sh

#!/bin/bash
rm -rf build; mkdir -p build
cd build && cmake .. && make -j5

3. 目录 sub，编译为动态库

// sub.h
#pragma once
int test_sub(int a, int b);

// sub.cpp
#include "sub.h"
int test_sub(int a, int b)
{
    return a-b;
}

执行脚本 add_build.sh

#!/bin/bash
rm -rf build; mkdir -p build
cd build && cmake .. && make -j5

将减法运算编译为动态库

# CMakeLists.txt
cmake_minimum_required(VERSION 2.8)
project(sub_shared)

# 搜索当前目录下的所有.cpp文件
aux_source_directory(${CMAKE_CURRENT_LIST_DIR} src_list) 

# 生成动态库
set(libname sub)
add_library(${libname} SHARED ${src_list})

执行脚本

#!/bin/bash
rm -rf build; mkdir -p build
cd build && cmake .. && make -j5

4. main函数

// main.cpp
#include <iostream>
#include "add.h"
#include "sub.h"
using namespace std;

int main()
{
    cout << "test_add 10+2 = " << test_add(10, 2) << endl;
    cout << "test_sub 10-2 = " << test_sub(10, 2) << endl;
    return 0;
}

CMakeLists.txt 使用

cmake_minimum_required(VERSION 2.8)

# set the project name
project(test)
message("test_BINARY_DIR: "${test_BINARY_DIR})
message("test_SOURCE_DIR: "${test_SOURCE_DIR})
message("PROJECT_BINARY_DIR: "${PROJECT_BINARY_DIR})
message("PROJECT_SOURCE_DIR: "${PROJECT_SOURCE_DIR})
message("CMAKE_CURRENT_SOURCE_DIR: "${CMAKE_CURRENT_SOURCE_DIR})
message("工程的根目录: "${PROJECT_SOURCE_DIR})

set(cur_dir   ${CMAKE_CURRENT_LIST_DIR})
set(add_dir         ${cur_dir}/add)
set(sub_dir         ${cur_dir}/sub)

include_directories(
    ${add_dir}
    ${sub_dir}
)

set(exe_name test)

IF(CMAKE_BUILD_METHOD STREQUAL 1)       # 按照字母表顺序比较。只和1匹配
    message("方法一 编译指定的文件")
    add_executable(${exe_name} main.cpp ${add_dir}/add.cpp ${sub_dir}/sub.cpp)

    # 设置 release
    message("release mode")
    SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O2")
    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -O2")

ELSEIF(CMAKE_BUILD_METHOD EQUAL 2)
    message("方法二 编译搜索目录下的文件") # 数字比较。只和2匹配
    # 搜索当前目录下的所有.cpp文件
    aux_source_directory (${add_dir} SRC_LIST) 
    aux_source_directory (${sub_dir} SRC_LIST)  
    
    # 设置 debug
    message("debug mode")
    SET(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g")
    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g")

    # 生成可执行文件
    add_executable(${exe_name} main.cpp ${SRC_LIST})

ELSEIF(CMAKE_BUILD_METHOD MATCHES 3)  # 给定的变量或者字符串能够匹配正则表达式 regex 时为真。
    message("方法三 库——使用查找指定库文件(find_library)")
    # 查找指定的库文件
    find_library(test_add_lib libadd.a ${add_dir}/build/)
    find_library(test_sub_lib libsub.so ${sub_dir}/build/)

    # 设置变量的值
    set(src_files_exe_name main.cpp)

    # 生成可执行文件
    add_executable(${exe_name} ${src_files_exe_name})

    # 指定链接多个库
    target_link_libraries(${exe_name} ${test_add_lib} ${test_sub_lib})

ELSE()
    message("方法四 库——设置链接库搜索目录(link_directories)")
    # 设置链接库搜索目录
    link_directories(
        ${add_dir}/build
        ${sub_dir}/build
    )

    # 生成可执行文件
    set(src_files_exe_name main.cpp)
    add_executable(${exe_name} ${src_files_exe_name})

    # 指定链接多个库
    set(test_lib libadd.a libsub.so)
    target_link_libraries(${exe_name} ${test_lib})
ENDIF()

执行脚本

#!/bin/bash
method=$1
rm -rf build; mkdir -p build
cd build && cmake .. -DCMAKE_BUILD_METHOD=${method} && make -j5

./test

5. 执行结果

执行如下语句，结果都是一样。
./main_build.sh 1
./main_build.sh 2
./main_build.sh 3
./main_build.sh 4

./main_build.sh 1 

test_BINARY_DIR: /data/neilnie/mypro/pro/cmake/build
test_SOURCE_DIR: /data/neilnie/mypro/pro/cmake
PROJECT_BINARY_DIR: /data/neilnie/mypro/pro/cmake/build
PROJECT_SOURCE_DIR: /data/neilnie/mypro/pro/cmake
CMAKE_CURRENT_SOURCE_DIR: /data/neilnie/mypro/pro/cmake
工程的根目录: /data/neilnie/mypro/pro/cmake
方法一 编译指定的文件
release mode
Linking CXX executable test
[100%] Built target test
test_add 10+2 = 12
test_sub 10-2 = 8

二. Cmake 简介

cmake 是一个跨平台、开源的构建系统。它是一个集软件构建、测试、打包于一身的软件。它使用与平台和编译器独立的配置文件来对软件编译过程进行控制.

三、常用变量

1. 预定义变量

PROJECT_SOURCE_DIR：工程的根目录
PROJECT_BINARY_DIR：运行 cmake 命令的目录，通常是 ${PROJECT_SOURCE_DIR}/build
CMAKE_CURRENT_SOURCE_DIR：当前处理的 CMakeLists.txt 所在的路径
CMAKE_CURRENT_LIST_DIR：CMakeLists.txt 的完整路径
PROJECT_NAME：返回通过 project 命令定义的项目名称
CMAKE_CURRENT_BINARY_DIR：target 编译目录
CMAKE_CURRENT_LIST_LINE：当前所在的行
CMAKE_MODULE_PATH：定义自己的 cmake 模块所在的路径，SET(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)，然后可以用INCLUDE命令来调用自己的模块
EXECUTABLE_OUTPUT_PATH：重新定义目标二进制可执行文件的存放位置
LIBRARY_OUTPUT_PATH：重新定义目标链接库文件的存放位置

2. 环境变量

使用环境变量

 $ENV{Name}

写入环境变量

 set(ENV{Name} value) # 这里没有“$”符号

3. 系统信息

CMAKE_MAJOR_VERSION：cmake 主版本号，比如 3.4.1 中的 3
CMAKE_MINOR_VERSION：cmake 次版本号，比如 3.4.1 中的 4
CMAKE_PATCH_VERSION：cmake 补丁等级，比如 3.4.1 中的 1
CMAKE_SYSTEM：系统名称，比如 Linux-2.6.22
CMAKE_SYSTEM_NAME：不包含版本的系统名，比如 Linux
CMAKE_SYSTEM_VERSION：系统版本，比如 2.6.22
CMAKE_SYSTEM_PROCESSOR：处理器名称，比如 i686
UNIX：在所有的类 UNIX 平台下该值为 TRUE，包括 OS X 和 cygwin
WIN32：在所有的 win32 平台下该值为 TRUE，包括 cygwin

查看cmake版本： cmake --version

4. 主要开关选项

BUILD_SHARED_LIBS：这个开关用来控制默认的库编译方式，如果不进行设置，使用 add_library 又没有指定库类型的情况下，默认编译生成的库都是静态库。如果 set(BUILD_SHARED_LIBS ON) 后，默认生成的为动态库。
CMAKE_C_FLAGS：设置 C 编译选项，也可以通过指令 add_definitions() 添加。
CMAKE_CXX_FLAGS：设置 C++ 编译选项，也可以通过指令 add_definitions() 添加。

add_definitions(-DENABLE_DEBUG -DABC) # 参数之间用空格分隔

四. 常用命令

1. 指定 cmake 的最小版本

cmake_minimum_required(VERSION 2.8)

这行命令是可选的，我们可以不写这句话，但在有些情况下，如果 CMakeLists.txt 文件中使用了一些高版本 cmake 特有的一些命令的时候，就需要加上这样一行，提醒用户升级到该版本之后再执行 cmake。

2. 设置项目名称

project(test)

这个命令不是强制性的，但最好都加上。它会引入两个变量 demo_BINARY_DIR 和 demo_SOURCE_DIR，同时，cmake 自动定义了两个等价的变量 PROJECT_BINARY_DIR 和 PROJECT_SOURCE_DIR。

project(test)
message("test_BINARY_DIR: "${test_BINARY_DIR})
message("test_SOURCE_DIR: "${test_SOURCE_DIR})
message("PROJECT_BINARY_DIR: "${PROJECT_BINARY_DIR})
message("PROJECT_SOURCE_DIR: "${PROJECT_SOURCE_DIR})

编译打印信息：

// /data/neilnie/mypro/pro/cmake/CMakeLists.txt
test_BINARY_DIR: /data/neilnie/mypro/pro/cmake/build  
test_SOURCE_DIR: /data/neilnie/mypro/pro/cmake  
PROJECT_BINARY_DIR: /data/neilnie/mypro/pro/cmake/build  
PROJECT_SOURCE_DIR: /data/neilnie/mypro/pro/cmake

3. 设置编译类型

add_executable(test main.cpp) # 生成可执行文件
add_library(common STATIC add.cpp) # 生成静态库
add_library(common SHARED add.cpp) # 生成动态库或共享库

add_library 默认生成是静态库

4. 指定编译包含的源文件

4.1 明确指定包含哪些源文件

// 生成可执行文件 test
add_executable(test main.cpp ${add_dir}/add.cpp ${sub_dir}/subtract.cpp)    

// 生成静态库 libtest.a
add_library(test main.cpp ${add_dir}/add.cpp ${sub_dir}/subtract.cpp)

4.2 搜索所有的 cpp 文件

aux_source_directory(dir VAR) 发现一个目录下所有的源代码文件并将列表存储在一个变量中。

aux_source_directory(. SRC_LIST) # 搜索当前目录下的所有.cpp文件
add_library(test ${SRC_LIST})   # 生成静态库 libtest.a

4.3 自定义搜索规则

file(GLOB SRC_LIST "*.cpp" "protocol/*.cpp")
add_library(test ${SRC_LIST})   # 生成静态库 libtest.a

# 或者
file(GLOB SRC_LIST "*.cpp")
file(GLOB SRC_PROTOCOL_LIST "protocol/*.cpp")
add_library(test ${SRC_LIST} ${SRC_PROTOCOL_LIST})

# 或者
file(GLOB_RECURSE SRC_LIST "*.cpp") #递归搜索
FILE(GLOB SRC_PROTOCOL RELATIVE "protocol" "*.cpp") # 相对protocol目录下搜索
add_library(test ${SRC_LIST} ${SRC_PROTOCOL_LIST})

# 或者
aux_source_directory(. SRC_LIST)
aux_source_directory(protocol SRC_PROTOCOL_LIST)
add_library(test ${SRC_LIST} ${SRC_PROTOCOL_LIST})

5. 查找指定的库文件

find_library(VAR name path)查找到指定的预编译库，并将它的路径存储在变量中。
默认的搜索路径为 cmake 包含的系统库，因此如果是 NDK 的公共库只需要指定库的 name 即可。

find_library( # Sets the name of the path variable.
              log-lib
 
              # Specifies the name of the NDK library that
              # you want CMake to locate.
              log )

类似的命令还有 find_file()、find_path()、find_program()、find_package()。

6. 设置包含的目录

include_directories(
    ${CMAKE_CURRENT_SOURCE_DIR}
    ${CMAKE_CURRENT_BINARY_DIR}
    ${CMAKE_CURRENT_SOURCE_DIR}/include
)

Linux 下还可以通过如下方式设置包含的目录

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -I${CMAKE_CURRENT_SOURCE_DIR}")

7. 设置链接库搜索目录

link_directories(
    ${CMAKE_CURRENT_SOURCE_DIR}/libs
)

Linux 下还可以通过如下方式设置包含的目录

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -L${CMAKE_CURRENT_SOURCE_DIR}/libs")

8. 设置 target 需要链接的库

target_link_libraries( # 目标库
                       exe_name
 
                       # 目标库需要链接的库
                       # test_lib、test_sub_lib 是上面 find_library 指定的变量名
                       ${test_lib} 
                       ${test_sub_lib})

在 Windows 下，系统会根据链接库目录，搜索xxx.lib 文件，Linux 下会搜索 xxx.so 或者 xxx.a 文件，如果都存在会优先链接动态库（so 后缀）。

8.1 指定链接动态库或静态库

target_link_libraries(test libadd.a) # 链接libface.a
target_link_libraries(test libsub.so) # 链接libface.so

# 或者
target_link_libraries(test libadd.a libsub.so)

8.2 指定全路径

target_link_libraries(test ${CMAKE_CURRENT_LIST_DIR}/add/libadd.a)
target_link_libraries(test ${CMAKE_CURRENT_LIST_DIR}/sub/libsub.so)

8.3 指定链接多个库

target_link_libraries(demo
    ${CMAKE_CURRENT_SOURCE_DIR}/libs/libface.a
    boost_system.a
    boost_thread
    pthread)

9. 命令行选项

-D

-D 相当于就是定义, -D 可以理解为告诉cmake 后边我要定义一些参数了, 你每定义一个就在前边加上-D就是了。
CMAKE_BUILD_TYPE 这种东西往往是在CMakeList.txt 中定义的，这个是你要编译的类型，一般的选择有debug，release，但是不确定。
CMAKE_INSTALL_PREFIX 这个是安装路径。

例子：

cmake -DCMAKE_BUILD_TYPE=Debug

10. 设置变量

10.1 set 直接设置变量的值

set(SRC_LIST main.cpp test.cpp)
add_executable(demo ${SRC_LIST})

10.2 set 追加设置变量的值

set(SRC_LIST main.cpp)
set(SRC_LIST ${SRC_LIST} test.cpp)
add_executable(demo ${SRC_LIST})

10.3 list 追加或者删除变量的值

set(SRC_LIST main.cpp)
list(APPEND SRC_LIST test.cpp)
list(REMOVE_ITEM SRC_LIST main.cpp)
add_executable(demo ${SRC_LIST})

备注，依赖的库升级了但部分文件有依赖不需要包含，可以通过 REMOVE_ITEM 移除。例如：
list(REMOVE_ITEM exe_name ${add_dir}/add.cpp)

11. 条件控制

11.1 if条件命令解析

if…elseif…else…endif

if(expression)
  # then section.
  COMMAND1(ARGS ...)
  COMMAND2(ARGS ...)
  ...
elseif(expression2)
  # elseif section.
  COMMAND1(ARGS ...)
  COMMAND2(ARGS ...)
  ...
else()
  # else section.
  COMMAND1(ARGS ...)
  COMMAND2(ARGS ...)
  ...
endif()

逻辑判断和比较：
if (expression)：expression 不为空（0,N,NO,OFF,FALSE,NOTFOUND）时为真
if (not exp)：与上面相反
if (var1 AND var2)
if (var1 OR var2)
if (COMMAND cmd)：如果 cmd 确实是命令并可调用为真
if (EXISTS dir) if (EXISTS file)：如果目录或文件存在为真
if (file1 IS_NEWER_THAN file2)：当 file1 比 file2 新，或 file1/file2 中有一个不存在时为真，文件名需使用全路径
if (IS_DIRECTORY dir)：当 dir 是目录时为真
if (DEFINED var)：如果变量被定义为真
if (var MATCHES regex)：给定的变量或者字符串能够匹配正则表达式 regex 时为真，此处 var 可以用 var 名，也可以用 ${var}
if (string MATCHES regex)

数字比较：
if (variable LESS number)：LESS 小于
if (string LESS number)
if (variable GREATER number)：GREATER 大于
if (string GREATER number)
if (variable EQUAL number)：EQUAL 等于
if (string EQUAL number)

字母表顺序比较：
if (variable STRLESS string)
if (string STRLESS string)
if (variable STRGREATER string)
if (string STRGREATER string)
if (variable STREQUAL string)
if (string STREQUAL string)

正则表达式：http://regex.800m.net/

例子参考，前文示例。

11.2 while…endwhile

while(condition)
    ...
endwhile()

11.3 foreach…endforeach

foreach(loop_var RANGE start stop [step])
    ...
endforeach(loop_var)

start 表示起始数，stop 表示终止数，step 表示步长，示例：

foreach(i RANGE 1 9 2)
    message(${i})
endforeach(i)
# 输出：13579

12. 打印信息

message(${PROJECT_SOURCE_DIR})
message("build with debug mode")
message(WARNING "this is warnning message")
message(FATAL_ERROR "this build has many error") # FATAL_ERROR 会导致编译失败

13. 包含其它 cmake 文件

include(./common.cmake) # 指定包含文件的全路径
include(def) # 在搜索路径中搜索def.cmake文件
set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake) # 设置include的搜索路径

本文内容由网友自发贡献，版权归原作者所有，本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容，请联系:hwhale#tublm.com(使用前将#替换为@)