调用 Delphi DLL 的意外线程行为

继续我的另一个问题：如何将内存流从我的应用程序传递到 DLL 或从 DLL 检索内存流？

我已经使用 DLL 编写了IStream作为输入/输出。该DLL使用IXMLDocument（起初我认为这与以下问题有关） 测试了一下，在主 UI 中运行良好。当我从工作线程调用 DLL 时，问题就开始了。

The DLL:

library MyDLL;

uses
  Windows,
  Variants,
  SysUtils,
  Classes,
  AxCtrls,
  ActiveX,
  XMLDoc,
  XMLIntf;

{$R *.res}    

procedure Debug(V: Variant);
begin
  OutputDebugString(PChar(VarToStr(V)));
end;

procedure DoProcess(InStream, OutStream: TStream);
var
  Doc: IXMLDocument;
begin
  InStream.Position := 0;
  Doc := TXMLDocument.Create(nil);
  Doc.LoadFromStream(InStream);
  // plans to do some real work...
  OutStream.Position := 0;
  Debug('MyDLL DoProcess OK');
end;

function Process(AInStream, AOutStream: IStream): Integer; stdcall;
var
  InStream, OutStream: TStream;
begin
  try
    InStream := TOleStream.Create(AInStream);
    try
      OutStream := TOleStream.Create(AOutStream);
      try
        DoProcess(InStream, OutStream);
        Result := 0;
      finally
        OutStream.Free;
      end;
    finally
      InStream.Free;
    end;
  except
    on E: Exception do
    begin
      Result := -1;
      Debug('MyDLL Error: ' + E.Message);
    end;
  end;
end;

exports
  Process;

begin
end.

我的来电应用程序：

implementation

uses
  ActiveX,ComObj;

{$R *.dfm}

procedure Debug(V: Variant);
begin
  OutputDebugString(PChar(VarToStr(V)));
end;

const
  MyDLL = 'MyDLL.dll';

{$DEFINE STATIC_DLL}
{$IFDEF STATIC_DLL}
function Process(AInStream, AOutStream: IStream): Integer; stdcall; external MyDLL;
{$ENDIF}

type
  // Dynamic
  TDLLProcessProc = function(AInStream, AOutStream: IStream): Integer; stdcall;

function DLLProcess(AInStream, AOutStream: TStream): Integer;
var
  InStream, OutStream: IStream;
  Module: HMODULE;
  DLLProc: TDLLProcessProc;
begin
  InStream := TStreamAdapter.Create(AInStream, soReference);
  OutStream := TStreamAdapter.Create(AOutStream, soReference);
{$IFDEF STATIC_DLL}
  Result := Process(InStream, OutStream); // Static
  Exit;
{$ENDIF}
  // Dynamic load DLL ...
  Module := LoadLibrary(MyDLL);
  if Module = 0 then RaiseLastOSError;
  try
    DLLProc := GetProcAddress(Module, 'Process');
    if @DLLProc = nil then RaiseLastOSError;
    Result := DLLProc(InStream, OutStream);
  finally
    FreeLibrary(Module);
  end;
end;

type
  TDLLThread = class(TThread)
  private
    FFileName: string;
  public
    constructor Create(CreateSuspended: Boolean; AFileName: string);
    procedure Execute(); override;
  end;

constructor TDLLThread.Create(CreateSuspended: Boolean; AFileName: string);
begin
  FreeOnTerminate := True;
  FFileName := AFileName;
  inherited Create(CreateSuspended);
end;

procedure TDLLThread.Execute;
var
  InStream, OutStream: TMemoryStream;
  RetValue: Integer;
begin
  try
    //CoInitializeEx(nil, COINIT_APARTMENTTHREADED);
    CoInitialize(nil);
    try
      InStream := TMemoryStream.Create;
      try
        InStream.LoadFromFile(FFileName);
        OutStream := TMemoryStream.Create;
        try
          RetValue := DLLProcess(InStream, OutStream);
          Sleep(0);
          Debug('TDLLThread Result=> ' + IntToStr(RetValue));
          if RetValue = 0 then
          begin
            Debug('TDLLThread OK');
          end;
        finally
          OutStream.Free;
        end;
      finally
        InStream.Free;
      end;
    finally
      CoUninitialize;
    end;
  except
    on E: Exception do
    begin
      Debug('TDLLThread Error: ' + E.Message);
    end;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject); // Test
var
  I: Integer;
begin
  for I := 1 to 5 do
    TDLLThread.Create(False, '1.xml');
end;

当运行一些测试时我有时获取即使异常块也无法捕获的访问冲突。程序就崩溃了Runtime error 216 at xxxxxxx or Invalid pointer operation.

我尝试过静态和动态 DLL 链接（图maybe动态链接在 LoadLibrary/FreeLibrary 中存在竞争条件）。

首先我想到IXMLDocument主要问题是：

Doc := TXMLDocument.Create(nil);
Doc.LoadFromStream(InStream);

有时，这会随机失败，没有明显的原因：

在顶层无效 文档。

Or:

名称以无效字符开头。

我想也许它使用了一些共享资源。但即使省略这些行引发AV！

所以 DLL 实际上没有做任何特别的事情。 我也没有看到任何可能感染的特殊情况DLLMain.

我不知道发生了什么事...有人可以建议如何处理这种情况吗？ （有人可以重现这种行为吗？）

编辑：我只是想添加一个相关的问题（类似IsMultiThread解决方案）：Delphi DLL - 线程安全

以及一些关于IsMultiThread: Is多线程变量

Delphi 中的内存管理器针对单线程使用进行了优化。这些是默认启用的。如果您的代码是多线程的，那么需要禁用此优化。通过设置来做到这一点IsMultiThread to True.

在创建 Delphi 线程的模块中，框架设置IsMultiThread to True当创建一个线程时。在您的程序中，线程是由主机创建的，因此库中没有设置任何内容IsMultiThread to True。因此您必须在 DLL 中显式地执行此操作。在库 .dpr 文件的主要部分中写入以下内容：

begin
  IsMultiThread := True;
end.