使用批处理文件按键盘按键[关闭]

我正在尝试开发一个批处理文件，它可以自动按向左箭头和向右箭头键 n 次，中间有一些暂停。有人可以帮我解决这个问题吗？

P.S：我尝试安装自动键盘软件，但由于我在工作而无法安装它们。我需要这个程序在我的办公室电脑上运行。

哇！这是否意味着您必须学习不同的编程语言才能将两个键发送到键盘？有更简单的方法可以让您实现同样的目标。:-)

下面的批处理文件是启动另一个程序（本例中为 cmd.exe）、向其发送命令，然后发送向上箭头键的示例，这会导致恢复上次执行的命令。批处理文件非常简单，易于理解，因此您可以对其进行修改以满足您的需要。

@if (@CodeSection == @Batch) @then


@echo off

rem Use %SendKeys% to send keys to the keyboard buffer
set SendKeys=CScript //nologo //E:JScript "%~F0"

rem Start the other program in the same Window
start "" /B cmd

%SendKeys% "echo off{ENTER}"

set /P "=Wait and send a command: " < NUL
ping -n 5 -w 1 127.0.0.1 > NUL
%SendKeys% "echo Hello, world!{ENTER}"

set /P "=Wait and send an Up Arrow key: [" < NUL
ping -n 5 -w 1 127.0.0.1 > NUL
%SendKeys% "{UP}"

set /P "=] Wait and send an Enter key:" < NUL
ping -n 5 -w 1 127.0.0.1 > NUL
%SendKeys% "{ENTER}"

%SendKeys% "exit{ENTER}"

goto :EOF


@end


// JScript section

var WshShell = WScript.CreateObject("WScript.Shell");
WshShell.SendKeys(WScript.Arguments(0));

有关 SendKeys 的键名称列表，请参阅：http://msdn.microsoft.com/en-us/library/8c6yea83(v=vs.84).aspx http://msdn.microsoft.com/en-us/library/8c6yea83(v=vs.84).aspx

例如：

LEFT ARROW    {LEFT}
RIGHT ARROW   {RIGHT}

有关此解决方案的进一步说明，请参阅：与 WebSphere MQ 服务器的 GnuWin32 openssl s_client conn 未在 EOF 处关闭，挂起 https://stackoverflow.com/questions/16823068/gnuwin32-openssl-s-client-conn-to-websphere-mq-server-not-closing-at-eof-hangs/16868982#16868982