如何在 MASM 中编写远绝对 JMP/CALL 指令？

如何使用 MASM 编写远绝对 JMP 或 CALL 指令？具体来说，如何让它使用 EA 和 CA 操作码发出这些指令，而不使用 DB 或其他数据指令手动发出它们？

例如，考虑跳转到引导扇区中 FFFF:0000 处的 BIOS 重置入口点的情况。如果我使用 NASM，我可以用一条指令以显而易见的方式对其进行编码：

jmp 0xffff:0

对于 GNU 汇编器，语法不太明显，但以下内容可以完成这项工作：

jmp 0xffff, 0

然而，当我尝试使用 MASM 的明显解决方案时：

jmp 0ffffh:0

我收到以下错误：

t206b.asm(3) : error A2096:segment, group, or segment register expected

我试图避免的解决方法

我可以在 MASM 中使用多种可能的解决方法，例如以下任意一种：

手动汇编指令，手动发出机器代码：

    DB 0EAh, 0, 0, 0FFh, 0FFh

使用远间接跳转：

bios_reset DD 0ffff0000h
    ...
    jmp bios_reset   ; FF 2E opcode: indirect far jump

或者将地址压入堆栈并使用远 RET 指令“返回”到该地址：

    push 0ffffh
    push 0
    retf

但是我是否可以使用实际的 JMP 指令并让 MASM 生成正确的操作码 (EA)？

有一种方法可以做到这一点，但你需要使用 MASM/omf切换以生成 OMF 格式的目标文件。这意味着目标文件需要与 OMF 兼容链接器链接，例如 Microsoft 的旧分段链接器（而不是当前的 32 位链接器）。

为此，您需要使用 MASM 的一个很少使用且不太了解的功能，即SEGMENT指令的AT address属性。这AT属性告诉链接器该段位于内存中的固定段落地址，如下所示address。它还告诉链接器丢弃该段，这意味着不使用该段的内容，仅使用其标签。这也是为什么/omf必须使用开关。 MASM 的默认目标文件格式 PECOFF 不支持此功能。

The AT属性为您提供了我们要跳转到的地址的段部分。要获取偏移部分，您需要做的就是在段内使用 LABEL 指令。与 ORG 指令结合使用，您可以在特定段中的特定偏移处创建标签。然后您需要做的就是在 JMP 或 CALL 指令中使用此标签。

例如，如果您想跳转到 BIOS 重置例程，您可以这样做：

bios_reset_seg SEGMENT USE16 AT 0ffffh
bios_reset LABEL FAR
bios_reset_seg ENDS

_TEXT SEGMENT USE16 'CODE'
    jmp bios_reset
_TEXT ENDS

或者，如果您想调用引导加载程序的第二阶段部分，其入口点位于 0000:7E00：

zero_seg SEGMENT USE16 AT 0
    ORG 7e00h
second_stage LABEL FAR
zero_seg ENDS

_TEXT SEGMENT USE16 'CODE'
    call second_stage
_TEXT ENDS